정상 상태 Modelica 모델에서 구성 요소 스테이징 해결

Question

Modelica를 사용하여 단순 정상 상태 구성 요소 스테이징 문제를 해결해야한다고 생각하지만 해결책을 찾기 위해 고심하고 있습니다.

나는 목표 총 유량을 시스템 (vTotal)에 전달해야하는 두 개의 병렬 펌프를 가진 예제 케이스를 준비했습니다. 하나의 펌프는 가변 주파수 펌프이며 명령 주파수 (fPump1)에 비례하는 유량 (v1)을 제공하며 0과 fMax 사이에서 변할 수 있습니다. 다른 펌프는 고정 속도 펌프이며, 실행 중일 때마다 고정 유속 (v2IfRunning)을 출력하고 실행 중이 지 않을 때는 제로 유량을 출력합니다.

목표는 실행중인 펌프 수와 변속 펌프 주파수를 해결하는 것입니다. 가변 속도 펌프는 항상 작동하고 고정 속도 펌프는 가변 속도 펌프가 fMax보다 큰 주파수에서 작동해야하는 경우에만 사용됩니다. 예제 코드는 다음과 같습니다.

model TwoPumpCode 
    // Pump 1 
    Modelica.SIunits.Frequency fPump1 "pump 1 frequency"; 
    Modelica.SIunits.Frequency fMax = 50 "maximum frequency"; 
    Modelica.SIunits.VolumeFlowRate v1; 

    // Pump 2 
    // Boolean runPump2(start=false) "true if pump 2 should run"; 
    Modelica.SIunits.VolumeFlowRate v2IfRunning = 30; 
    Modelica.SIunits.VolumeFlowRate v2 
    "actual flow through pump 2"; 

    Integer nPumpsRunning(start = 1) "number of pumps running"; 

    // Total flow 
    Modelica.SIunits.VolumeFlowRate vTotal = 70; 

equation 
    // Calculate the flow through pump 1 as a function of frequency 
    v1 = fPump1; 

    // Calculate the flow through pump 2 based upon running state 
    if fPump1 > fMax then 
    nPumpsRunning = 2; 
    v2 = v2IfRunning; 
    else 
    nPumpsRunning = 1; 
    v2 = 0; 
    end if; 

    // Calculate the total flow 
    vTotal = v1 + v2; 

end TwoPumpCode; 

다시 말하지만 정상 상태 모델입니다. if, when, reinit, pumpRunning 상태에 대한 Boolean 변수, 실행중인 펌프 수에 대한 Integer 변수 등을 사용해 보았습니다. 아직 해결할 정상 상태 솔루션을 얻을 수 없습니다.

의견을 보내 주시면 대단히 감사하겠습니다.

덕분에, 저스틴

Answer 1

지금은 더 잘 이해합니다. 문제는 변수를 분리해야한다는 것입니다.

model TwoPumpCode 
    Modelica.SIunits.VolumeFlowRate vTotal = 70-40*time; 
    model TwoPumpSimple 
    // Pump 1 
    Modelica.SIunits.Frequency fPump1 "pump 1 frequency"; 
    Modelica.SIunits.Frequency fMax = 50 "maximum frequency"; 
    Modelica.SIunits.VolumeFlowRate v1; 

    // Pump 2 
    // Boolean runPump2(start=false) "true if pump 2 should run"; 
    Modelica.SIunits.VolumeFlowRate v2IfRunning = 30; 
    Modelica.SIunits.VolumeFlowRate v2 
    "actual flow through pump 2"; 

    Integer nPumpsRunning(start = 1) "number of pumps running"; 
    // Total flow 
    input Modelica.SIunits.VolumeFlowRate vTotal; 
    input Boolean activeSecond; 
    equation 
    // Calculate the flow through pump 1 as a function of frequency 
    v1 = fPump1; 

    // Calculate the flow through pump 2 based upon running state 
    if activeSecond then 
    nPumpsRunning = 2; 
    v2 = v2IfRunning; 
    else 
    nPumpsRunning = 1; 
    v2 = 0; 
    end if; 

    // Calculate the total flow 
    vTotal = v1 + v2; 
    end TwoPumpSimple; 
    //TwoPumpSimple first(vTotal=vTotal,activeSecond=first.fPump1>first.fMax); 
    TwoPumpSimple first(vTotal=vTotal,activeSecond=false); 
    TwoPumpSimple second(vTotal=vTotal,activeSecond=first.fPump1>first.fMax); 
end TwoPumpCode; 

아웃 주석 라인은 최초의 솔루션과 동일하고, 이산 문제로 변경 -하지만 문제는 가끔 솔루션이 부족하다.

새로운 변형은 다음을 수행합니다. 1 두 번째 펌프가 없으면 얼마나 높은 빈도가 필요합니까?

2 2 차 펌프를 활성화해야합니까?

3 새로운 빈도를 계산하십시오.

결정에 일부 히스테리시스를 추가하면 유사한 효과가 있습니다.

Answer 2

matth의 피드백을 기반으로 Modelica.Blocks.Logical.OnOffController의 예제를 기반으로 pre() 연산자를 사용할 수있었습니다. 참조 용으로 기능 코드가 아래에 나와 있습니다.

model TwoPumpCode_matth 
    // Pump 1 
    Modelica.SIunits.Frequency fPump1 "pump 1 frequency"; 
    Modelica.SIunits.Frequency fMax = 50 "maximum frequency"; 
    Modelica.SIunits.VolumeFlowRate v1; 

    // Pump 2 
    parameter Boolean runPump2InitialValue = false; 
    Boolean runPump2(start=runPump2InitialValue) "true if pump 2 should run"; 
    Modelica.SIunits.VolumeFlowRate v2IfRunning = 30; 
    Modelica.SIunits.VolumeFlowRate v2 "actual flow through pump 2"; 

    // Total flow 
    Modelica.SIunits.VolumeFlowRate vTotal = 70; 

initial equation 
    pre(runPump2) = runPump2InitialValue; 

equation 
    // Calculate the flow through pump 1 as a function of frequency 
    v1 = fPump1; 

    // Calculate the flow through pump 2 based upon running state 
    runPump2 = pre(runPump2) or (fPump1 > fMax); 
    if runPump2 then 
    v2 = v2IfRunning; 

    else 
    v2 = 0; 

    end if; 

    // Calculate the total flow 
    vTotal = v1 + v2; 

end TwoPumpCode_matth;