Aeson - Haskell의 임의 JSON 키

Question

임의의 키가있는 중첩 JSON 객체가 여러 개 있습니다. A이 B, C이 미리 알 수

{ 
    "A": { 
     "B": { 
      "C": "hello" 

     } 
    } 

} 

. 이 세 사람은 각각 형제가있는 이 될 수도 있습니다.

Aeson이 사용자 정의 유형으로 이것을 구문 분석하는 방법이 있는지 궁금합니다. 몇 가지 우아한 방법입니다. 내가 한 일은 Aeson Object에로드하는 것입니다.

이런 종류의 JSON 개체에 대해 FromJSON을 어떻게 구현 하시겠습니까?

감사합니다.

편집는 :

{ 
    "USA": { 
     "California": { 
      "San Francisco": "Some text" 
     } 
    }, 
    "Canada": { 
     ... 
    } 
} 

이 ... CountryDatabase 곳으로 컴파일해야

type City   = Map String String 
type Country   = Map String City 
type CountryDatabase = Map String Country 

Answer 1

당신은 Map String v의 FromJSON 인스턴스를 다시 사용할 수 있습니다. 다음과 같은 뭔가 :

{-# LANGUAGE OverloadedStrings #-} 

import Data.Functor 
import Data.Monoid 
import Data.Aeson 
import Data.Map (Map) 
import qualified Data.ByteString.Lazy as LBS 
import System.Environment 

newtype City = City (Map String String) 
    deriving Show 

instance FromJSON City where 
    parseJSON val = City <$> parseJSON val 

newtype Country = Country (Map String City) 
    deriving Show 

instance FromJSON Country where 
    parseJSON val = Country <$> parseJSON val 

newtype DB = DB (Map String Country) 
    deriving Show 

instance FromJSON DB where 
    parseJSON val = DB <$> parseJSON val 

main :: IO() 
main = do 
    file <- head <$> getArgs 
    str <- LBS.readFile file 
    print (decode str :: Maybe DB) 

출력 :

shum@shum-lt:/tmp/shum$ cat in.js 
{ 
    "A": { 
     "A1": { 
      "A11": "1111", 
      "A22": "2222" 
     } 
    }, 
    "B": { 
    } 
} 
shum@shum-lt:/tmp/shum$ runhaskell test.hs in.js 
Just (DB (fromList [("A",Country (fromList [("A1",City (fromList [("A11","1111"),("A22","2222")]))])),("B",Country (fromList []))])) 
shum@shum-lt:/tmp/shum$ 

PS : 당신은 내가 단지 명확성을 위해 그들을 사용 newtype의없이 그것을 할 수 있습니다.