wikidata에서 부분 검색을 통해 모든 스포츠를 가져 오는 방법, 첫 번째 이미지 및 언어 검색

Question

SPARQL 및 wikidata로 2 일 동안 노력하고 모든 예제를 살펴 보았습니다. 내 요구에 가까운 예제를 찾지 못한 복잡한 쿼리를 찾는 데 도움이 필요합니다.

아이디어는 스포츠를 검색하여 첫 번째 이미지 (있는 경우)를 얻는 것입니다. 모든 언어의 레이블을 검색 할 수 있습니다. 아래에서 나는 작은 부분을 달성했지만 여기에 문제가 있습니다. 이 쿼리

1. , 나는 농구가 아니라 축구를 얻을 수있어, 나는 내가 그것을 제대로 작동했던 생각을 footbal 스포츠의 유형의 서브 클래스로 서브 클래스로 검색을하는 방법을 알아낼 수는 없지만 그것은 축구를 반환하지 않습니다.

2. 이미지를 가져 오려면 (옵션으로 시도한) 추가 할 때 복싱에 2 개의 이미지가 있기 때문에 "bodybuilding"을 2 행으로 반환합니다. 첫 번째 이미지 만있는 첫 번째 행 만 가져 오는 방법이 있습니까? 나는 뚜렷한 시도를하고 멀리 가지 않았다.

3. 이 경우 영어로 검색하지만 모든 언어로 된 라벨을 받고 싶습니다.

각 행은 1 개 스포츠는 모든 언어에서 "보", 첫 번째 이미지 및 레이블로 시작하는 것 10 행 것이 중 완벽한 결과는, 나는 키가 큰 순서 어쩌면 언어가 될 수 있음을 이해 다른 쿼리에서 요청해야하며 그렇다면 어떻게해야합니까?

#NOT WORKING AS EXPECTED/Need Help 
SELECT DISTINCT ?item ?label WHERE {   
    ?item wdt:P31/wdt:P279* wd:Q31629.  
    ?item rdfs:label ?label.   
FILTER((LANG(?label)) = "en")   
FILTER(STRSTARTS(lcase(?label), lcase("bo")))  
}   
LIMIT 10 

Answer 1

SAMPLE을 사용하면 스포츠별로 사진을 하나씩 얻을 수 있습니다. 모든 레이블이 필요하지만 각 언어를 별도로 정의하지 않고 스포츠 당 행이 하나만 있어야하는 경우 GROUP_CONCAT을 사용하여 레이블을 연결할 수 있습니다. 여러 값을 변수에 바인딩하려면 VALUES을 사용할 수 있습니다.

SELECT DISTINCT ?item (SAMPLE(?img) AS ?image) (GROUP_CONCAT(DISTINCT ?lbl; separator=', ') AS ?label) WHERE { 
    # Bind variable ?type to the types you want 
    VALUES ?type { wd:Q31629 wd:Q7128792 } 
    ?item wdt:P31 ?type . 
    # Search only English labels 
    ?item rdfs:label ?search_label . 
    FILTER(LANG(?search_label) = "en") 
    FILTER(STRSTARTS(lcase(?search_label), lcase("bo"))) 
    # Get all labels 
    ?item rdfs:label ?l . 
    # Produces strings like "bodybuilding (en)" 
    BIND(CONCAT(STR(?l), ' (', LANG(?l), ')') AS ?lbl) 
    # Get the images 
    OPTIONAL { 
     ?item wdt:P18 ?img . 
    } 
} 
GROUP BY ?item 
LIMIT 10 

Link to the above query in the Wikidata Query Service