XP에서 Windows 버전을 확인하기위한 배치 파일

Question

XP/2003 또는 7/R2에서 실행 중일 때 다르게 동작해야하는 설치 스크립트가 있습니다. 정상적으로 작동합니다. 몇 주 전 XPe에서 실행되지 않는다는 것을 알았습니다. (7e에서 잘 작동합니다.) find.exe는 XPe에 포함되어 있지 않습니다.

내 현재 스크립트가 사용

ver | find "5." > nul 
if %ERRORLEVEL% == 0 goto WinXP 
    goto Win7 

내가 실행 가능한 솔루션을 테스트하기 위해 동료의 XPe 장치를 빌려, 나는 프로 XP에서의 Find.exe을 복사했는데, 그것은 여전히 ​​작동하지 않았다. 나는 다양한 버전 (findxp.exe에 대한 전체 경로, with/without .exe)을 시도했지만 여전히 작동하지 않는다. 다음은 XPe의 결과입니다.

저는 XP/2003의 경우 정말 그렇습니다. 그렇지 않으면 Vista (하하) 또는 2008 또는 그 이상이라고 가정합니다. 그것이 XPe인지 말해 준 해결책에 반대하지는 않겠지 만, 장래에 유용 할 수도 있고 그렇지 않을 수도 있습니다. 그러나 모든 버전을 고려해야하므로 스크립트를 더 복잡하게 만들 것입니다. Windows의.

감사합니다, 브라이언

Answer 1

에서 아래의 코드 세그먼트가 필요하지 않은 원본 코드의 직접 대체 find.exe :

for /F "delims=" %%a in ('ver') do set ver=%%a 
if "%ver:5.=%" neq "%ver%" goto WinXP 
goto Win7 

Answer 2

@ECHO OFF 
SET OSVersion=Unknown 

VER | FINDSTR /L "5.0" > NUL 
IF %ERRORLEVEL% EQU 0 SET OSVersion=2000 

VER | FINDSTR /L "5.1." > NUL 
IF %ERRORLEVEL% EQU 0 SET OSVersion=XP 

VER | FINDSTR /L "5.2." > NUL 
IF %ERRORLEVEL% EQU 0 SET OSVersion=2003 

VER | FINDSTR /L "6.0." > NUL 
IF %ERRORLEVEL% EQU 0 SET OSVersion=Vista 

VER | FINDSTR /L "6.1." > NUL 
IF %ERRORLEVEL% EQU 0 SET OSVersion=7 

IF %OSVersion%==Unknown (
ECHO Unable to determine your version of Windows. 
) ELSE (
ECHO You appear to be using Windows %OSVersion% 
) 

ECHO. 
PAUSE 

Answer 3

아래를 확인하세요. 또한, 당신은 여기에 액세스 할 수 있습니다

vers 

것은이 표시됩니다 http://pastebin.com/iUtgN4ZU

@echo off 

ver | find "2003" > nul 
if %ERRORLEVEL% == 0 goto ver_2003 

ver | find "XP" > nul 
if %ERRORLEVEL% == 0 goto ver_xp 

ver | find "2000" > nul 
if %ERRORLEVEL% == 0 goto ver_2000 

ver | find "NT" > nul 
if %ERRORLEVEL% == 0 goto ver_nt 

if not exist %SystemRoot%\system32\systeminfo.exe goto warnthenexit 

systeminfo | find "OS Name" > %TEMP%\osname.txt 
FOR /F "usebackq delims=: tokens=2" %%i IN (%TEMP%\osname.txt) DO set vers=%%i 

echo %vers% | find "Windows 7" > nul 
if %ERRORLEVEL% == 0 goto ver_7 

echo %vers% | find "Windows Server 2008" > nul 
if %ERRORLEVEL% == 0 goto ver_2008 

echo %vers% | find "Windows Vista" > nul 
if %ERRORLEVEL% == 0 goto ver_vista 

goto warnthenexit 

:ver_7 
:Run Windows 7 specific commands here. 
echo Windows 7 
goto exit 

:ver_2008 
:Run Windows Server 2008 specific commands here. 
echo Windows Server 2008 
goto exit 

:ver_vista 
:Run Windows Vista specific commands here. 
echo Windows Vista 
goto exit 

:ver_2003 
:Run Windows Server 2003 specific commands here. 
echo Windows Server 2003 
goto exit 

:ver_xp 
:Run Windows XP specific commands here. 
echo Windows XP 
goto exit 

:ver_2000 
:Run Windows 2000 specific commands here. 
echo Windows 2000 
goto exit 

:ver_nt 
:Run Windows NT specific commands here. 
echo Windows NT 
goto exit 

:warnthenexit 
echo Machine undetermined. 

:exit 

이

vers.bat 그리고 명령 프롬프트에서 실행되는 후가 % windir % \로 파일을 저장 어떤 버전의 Windows.

Answer 4

이 시도 : Aacini ©

@echo off 
setlocal EnableDelayedExpansion 

::Identify OS 
for /F "delims=" %%a in ('ver') do set ver=%%a 
set Version= 
for %%a in (95=95 98=98 ME=ME NT=NT 2000=2000 5.1.=XP 5.2.=2003 6.0.=Vista 6.1.=7 6.2.=8) do (
    if "!Version!" equ "this" (
     set Version=Windows %%a 
    ) else if "!ver: %%a=!" neq "%ver%" (
     set Version=this 
    ) 
) 

::Identify bit 
if exist "%SYSTEMDRIVE%\Program Files (x86)" (
    set Type=64 bit 
) else (
    set Type=32 bit 
) 

::Display result 
echo %Version% %Type% 

을 dostips