Excel VBA를 사용하여 두 열의 값을 기반으로 열 합치기 및 합치기

Question

여기에 약간의 수수께끼가 있습니다 & 사이트에 대한 제안이 있지만 나에게 맞는 것은 없습니다. 행의 일부 셀 값을 기반으로 일부 행을 병합해야합니다.

나는 그 이름과 일치하는 일종의 코드가 필요하고 같은 이름을 가진 'New Starter'엔트리를 찾는다. 여기

은 얼마나 내 데이터 (시프트, 이름, 세부) 같습니다

 
09:00-17:00 Smith John  Present 
09:00-11:00 Smith John  New Starter 
11:10-13:00 Smith John  New Starter 
14:00-17:00 Smith John  New Starter 
09:00-17:00 Connor Sarah Present 
09:00-11:00 Connor Sarah New Starter 
11:10-13:00 Connor Sarah New Starter 
14:00-17:00 Connor Sarah New Starter 
09:00-17:00 Claus Santa  Present 
10:00-18:00 Mouse Mickey Present 
10:00-11:00 Mouse Mickey New Starter 
11:10-13:00 Mouse Mickey New Starter 
14:00-18:00 Mouse Mickey New Starter 

내가 (있는 경우) 새 스타터 줄을 제거뿐만 아니라 '새 스타터'로 자신의 '현재'셀을 교체해야 (필요한 경우이 다른 텍스트가 될 수 있지만) : 당신은 산타 새 스타터 & 아니라고 여기에서 볼 수 있습니다

 
09:00-17:00 Smith John  New Starter 
09:00-17:00 Connor Sarah New Starter 
09:00-17:00 Claus Santa  Present 
10:00-18:00 Mouse Mickey New Starter 

따라서 '현재'로 유지됩니다.

기본적으로 'New Starter'라인은 필요하지 않지만 새로운 스타터에게 현재 직원에게 다른 세부 사항을 제공하고자합니다.

추가 참고 :

• 는 '새로운 스타터'가 존재하는 경우 A '현재'라인은 항상 존재합니다. 그들이 'Day Day Off'를 가지고 있다면, 이미 다른 Subs에서 추출한 'Day Off'라인이있을 것입니다.
• 보존 할 데이터는 "현재"행에있는 것이므로 해당 제목 (C 열) 만 바꿉니다.

Answer 1

다음 코드는 조건을 설명합니다. 시험 작동.

Sub RemoveDups() 

Dim CurRow As Long, LastRow As Long, SrchRng As Range 

LastRow = Range("A" & Rows.Count).End(xlUp).Row 

    Range("A1:C" & LastRow).Select 
    Sheets(1).Sort.SortFields.Clear 
    Sheets(1).Sort.SortFields.Add Key:=Range("B2:B" & LastRow) _ 
     , SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal 
    Sheets(1).Sort.SortFields.Add Key:=Range("C2:C" & LastRow) _ 
     , SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal 
    With Sheets(1).Sort 
     .SetRange Range("A1:C" & LastRow) 
     .Header = xlYes 
     .MatchCase = False 
     .Orientation = xlTopToBottom 
     .SortMethod = xlPinYin 
     .Apply 
    End With 

For CurRow = LastRow To 2 Step -1 
    If Range("C" & CurRow).Value = "Present" Then 
     If CurRow <> 2 Then 
      If Not Range("B2:B" & CurRow - 1).Find(Range("B" & CurRow).Value, LookIn:=xlValues, LookAt:=xlWhole) is Nothing Then 
       Range("C" & CurRow).Value = "New Starter" 
      End If 
     End If 
    ElseIf Range("C" & CurRow).Value = "New Starter" Then 
     Range("C" & CurRow).EntireRow.Delete xlShiftUp 
    End If 
Next CurRow 

End Sub 

Answer 2

두 번째 방법은 데이터의 위치를 ​​고려하여 '일반'과 '휴대용'을 고려하는 것입니다. 당신이 통합하기 전에 데이터를 정렬하려면, 다음이 대체 사용 (더 오랜을?) Range.Sort 방법 호환 다시 Excel로 2003 또한 매개 변수를이 방법은 msdn reference, here

Option Explicit 
Sub newStarters() 
Dim ws As Worksheet 
Dim dRng As Range 
Dim stRow As Long, endRow As Long, nameCol As Long, c As Long 
Dim nme As String, changeStr As String 

'explicitly identify data sheet 
Set ws = Sheets("Data") 
'start row of data 
stRow = 2 
'column number of "Name" 
nameCol = 3 
'set changeStr 
changeStr = "New Starter" 

    'Use the explicit data sheet 
    With ws 
     'find last data row 
     endRow = .Cells(Rows.Count, nameCol).End(xlUp).Row 

     'if you want the data to be sorted before consolidating 
     '====================================================== 
     'Set dRng = .Range(.Cells(stRow, nameCol).Offset(0, -1), _ 
     '   .Cells(endRow, nameCol).Offset(0, 1)) 

     'dRng.Sort Key1:=.Cells(stRow, nameCol), Order1:=xlAscending, _ 
     '   Key2:=.Cells(stRow, nameCol).Offset(0, 1), Order2:=xlDescending, _ 
     '   Header:=xlNo 
     '====================================================== 
      'consolidate data 
      For c = endRow To stRow Step -1 
       With .Cells(c, nameCol) 
        nme = .Value 
         If .Offset(0, 1).Value = changeStr Then 
          If .Offset(-1, 0).Value = nme Then 
           .Offset(-1, 1).Value = changeStr 
           .EntireRow.Delete xlShiftUp 
          End If 
         End If 
       End With 
      Next c 
    End With 

End Sub