vb6 코드를 사용하여 대화 상자 컨트롤을 사용하지 않고 대화 상자를 엽니 다.

Question

일반 대화 상자 구성 요소/컨트롤을 사용하지 않고 대화 상자를 여는 프로젝트를 만드는 데 도움을주십시오.

감사 Sesha

Answer 1

CommonDialog 컨트롤은 VB에서 직접 호출 할 수 GetOpenFileName/GetSaveFileName API를 주위에 얇은 래퍼입니다. Here is a working example.

Answer 2

다음은 Microsoft KB의 샘플 코드입니다 (source).

Option Explicit 

Private Declare Function GetOpenFileName Lib "comdlg32.dll" Alias _ 
     "GetOpenFileNameA" (pOpenfilename As OPENFILENAME) As Long 

Private Type OPENFILENAME 
    lStructSize As Long 
    hwndOwner As Long 
    hInstance As Long 
    lpstrFilter As String 
    lpstrCustomFilter As String 
    nMaxCustFilter As Long 
    nFilterIndex As Long 
    lpstrFile As String 
    nMaxFile As Long 
    lpstrFileTitle As String 
    nMaxFileTitle As Long 
    lpstrInitialDir As String 
    lpstrTitle As String 
    flags As Long 
    nFileOffset As Integer 
    nFileExtension As Integer 
    lpstrDefExt As String 
    lCustData As Long 
    lpfnHook As Long 
    lpTemplateName As String 
End Type 

Private Sub Command1_Click() 
    Dim OpenFile As OPENFILENAME 
    Dim lReturn As Long 
    Dim sFilter As String 

    OpenFile.lStructSize = Len(OpenFile) 
    OpenFile.hwndOwner = Form1.hwnd 
    OpenFile.hInstance = App.hInstance 
    sFilter = "Batch Files (*.bat)" & Chr(0) & "*.BAT" & Chr(0) 
    OpenFile.lpstrFilter = sFilter 
    OpenFile.nFilterIndex = 1 
    OpenFile.lpstrFile = String(257, 0) 
    OpenFile.nMaxFile = Len(OpenFile.lpstrFile) - 1 
    OpenFile.lpstrFileTitle = OpenFile.lpstrFile 
    OpenFile.nMaxFileTitle = OpenFile.nMaxFile 
    OpenFile.lpstrInitialDir = "C:\" 
    OpenFile.lpstrTitle = "Use the Comdlg API not the OCX" 
    OpenFile.flags = 0 
    lReturn = GetOpenFileName(OpenFile) 
    If lReturn = 0 Then 
     MsgBox "The User pressed the Cancel Button" 
    Else 
     MsgBox "The user Chose " & Trim(OpenFile.lpstrFile) 
    End If 
End Sub 

Answer 3

당신은 vbAccelerator.com에서 아주 좋은 라이브러리를 사용할 수 있습니다 : -

Common Dialog Direct Library