PROLOG CLPFD 제약 조건을 통해이를 표현하는 방법은 무엇입니까?

Question

는 다음 코드 샘플을 감안할 때 :

이

example(Ls) :- 
    Ls = [X,Y], 
    Ls ins 1..2, 
    Cost #= max((X #= 1)*3 + (Y #= 1)*5, 
       (X #= 2)*3 + (Y #= 2)*5), 
    labeling([minimize(Cost)], Ls). 

아이디어는이 간단한 예제에서 (비용을 최소화 LS의 변수에 할당을 찾는 것입니다

, 그것은 것을 중 X = 1, Y = 2, 또는 X = 2 및 Y = 1).

제약 # =/2는 검증 할 수 있다는 사실을 이용하려고합니다. 이는 진리 값을 정수 0과 1로 표현 된 부울 값에 반영한다는 것을 의미합니다 (설명서 http://www.swi-prolog.org/man/clpfd.html에서 가져옴).

그러나 작동하지 않습니다. 다음 오류가 발생합니다.

ERROR: Domain error: `clpfd_expression' expected, found `_G3154#=1' 

무엇이 상응하는 올바른 버전입니까?

Answer 1

구체화는 예를 들어 사용할 수 있습니다, (등 #<==>/2, #==>/2)제약 별도의 포함과 같은 :

example(Ls) :- 
    Ls = [X,Y], 
    Ls ins 1..2, 
    X #= 1 #<==> B1, 
    Y #= 1 #<==> B2, 
    X #= 2 #<==> B3, 
    Y #= 2 #<==> B4, 
    Cost #= max(B1*3 + B2*5, B3*3 + B4*5), 
    labeling([min(Cost)], Ls). 

샘플 쿼리 및 그 결과 :

?- example(Ls). 
Ls = [1, 2] ; 
Ls = [2, 1] ; 
Ls = [1, 1] ; 
Ls = [2, 2] ; 
false. 

Answer 2

하는 대신 구체화를 사용하면 표현식에서 동등성을 "캡처"하기 위해 추가 산술 제약 조건을 사용할 수도 있습니다.

example([X,Y]) :- 
    X in 1..2, 
    Y in 1..2, 
    Cost #= max(3*(1-min(1,abs(X-1))) + 5*(1-min(1,abs(Y-1))), 
       3*(1-min(1,abs(X-2))) + 5*(1-min(1,abs(Y-2)))), 
    labeling([min(Cost)], [X,Y]). 

Cost #= max(...) 내부 표현은 약간 단순화 될 수 있습니다.

샘플 사용 :

?- example(Ls). 
    Ls = [1,2] 
; Ls = [2,1] 
; Ls = [1,1] 
; Ls = [2,2] 
; false.