Inno Setup - ProgressGauge bar 아래의 wp 설치 페이지에 여러 이미지 표시 (슬라이드 쇼)

Question

ProgressGauge 막대 아래의 이미지를 표시하는 간단한 스크립트를 wpInstalling 페이지에 준비했습니다.

하지만 더 복잡한 기능이 필요합니다.

설치가 X (예 : 7 초) (설치 시간이 길면 X 초 * 이미지 수가 늘어남) 또는 설치 후 X (예 : 10) 후에 각각 여러 이미지가 표시됩니다. ProgressGauge.Position에 이미지를 표시하려고했지만 실패했습니다. 여기

내가 무엇을 가지고 :

procedure CurPageChanged(CurPageID: Integer); 
var 
    BmpFile: TBitmapImage; 
begin 
    ExtractTemporaryFile('01.bmp'); 
    ExtractTemporaryFile('02.bmp'); 
    ExtractTemporaryFile('03.bmp'); 

    if CurPageID = wpInstalling then 
    begin 
    BmpFile:= TBitmapImage.Create(WizardForm); 
    BmpFile.Bitmap.LoadFromFile(ExpandConstant('{tmp}\01.bmp')); 
    BmpFile.Width:= ScaleX(420); 
    BmpFile.Height:= ScaleY(180); 
    BmpFile.Left := WizardForm.ProgressGauge.Left + ScaleX(0); 
    BmpFile.Top := WizardForm.ProgressGauge.Top + ScaleY(35); 

    // BmpFile.Parent:= WizardForm.InstallingPage; 
    // BmpFile:= TBitmapImage.Create(WizardForm); 
    // BmpFile.Bitmap.LoadFromFile(ExpandConstant('{tmp}\03.bmp')); 
    // BmpFile.Width:= ScaleX(420); 
    // BmpFile.Height:= ScaleY(400); 
    // BmpFile.Left := WizardForm.ProgressGauge.Left + ScaleX(0); 
    // BmpFile.Top := WizardForm.ProgressGauge.Top + ScaleY(35); 
    // BmpFile.Parent:= WizardForm.InstallingPage; 

    // BmpFile:= TBitmapImage.Create(WizardForm); 
    // BmpFile.Bitmap.LoadFromFile(ExpandConstant('{tmp}\03.bmp')); 
    // BmpFile.Width:= ScaleX(420); 
    // BmpFile.Height:= ScaleY(400); 
    // BmpFile.Left := WizardForm.ProgressGauge.Left + ScaleX(0); 
    // BmpFile.Top := WizardForm.ProgressGauge.Top + ScaleY(35); 
    // BmpFile.Parent:= WizardForm.InstallingPage; 
    end; 
end; 

목적은 다음과 같습니다 wpInstalling에
표시 X 이미지, X 초 당 또는 설치의 X 퍼센트 후마다 다음이 있어야합니다.

Answer 1

ProgressGauge에는 진행 변경 이벤트가 없으므로 설치 응용 프로그램 메시지를 처리 ​​할 방법이 없으므로 Windows API 타이머를 사용해야합니다. 이 타이머는 Inno Setup 스크립트에서 정의 할 수없는 콜백 함수를 필요로하기 때문에이 작업을 수행하기 위해 외부 라이브러리가 필요합니다. 그러나 정확하게 이것을 할 수있는 InnoCallback 라이브러리가 있습니다. 다음 코드를

이 설치 디렉토리에 InnoCallback.dll 라이브러리를 복사하여 이노 설치 스크립트를 사용하여이 코드를 병합하고 현재 설정 (초마다 주기적으로 호출 될 OnSlideTimer 이벤트에서 슬라이드 쇼 페이지 터닝 어떤 종류의 구현).

[Files] 
Source: "InnoCallback.dll"; DestDir: "{tmp}"; Flags: dontcopy 

[code] 
var 
    TimerID: Integer; 

type 
    TTimerProc = procedure(Wnd: HWND; Msg: UINT; TimerID: UINT_PTR; 
    SysTime: DWORD); 

function WrapTimerProc(Callback: TTimerProc; ParamCount: Integer): LongWord; 
    external 'wrapcallback@files:InnoCallback.dll stdcall';  
function SetTimer(hWnd: HWND; nIDEvent, uElapse: UINT; 
    lpTimerFunc: UINT): UINT; external 'SetTimer@user32.dll stdcall'; 
function KillTimer(hWnd: HWND; uIDEvent: UINT): BOOL; 
    external 'KillTimer@user32.dll stdcall'; 

procedure OnSlideTimer(Wnd: HWND; Msg: UINT; TimerID: UINT_PTR; 
    SysTime: DWORD); 
begin 
    { here you can turn your slideshow pages; use some variable to store the } 
    { current index of the slide you are on, note that this procedure is called } 
    { periodically each 1000 ms (see below why), so here you can also check the } 
    { progress value, if you want to } 
end; 

procedure StartSlideTimer; 
var 
    TimerCallback: LongWord; 
begin 
    TimerCallback := WrapTimerProc(@OnSlideTimer, 4); 
    { third parameter here is the timer's timeout value in milliseconds } 
    TimerID := SetTimer(0, 0, 1000, TimerCallback); 
end; 

procedure KillSlideTimer; 
begin 
    if TimerID <> 0 then 
    begin 
    if KillTimer(0, TimerID) then 
     TimerID := 0; 
    end; 
end; 

function InitializeSetup: Boolean; 
begin 
    Result := True; 
    TimerID := 0; 
end; 

procedure DeinitializeSetup; 
begin 
    KillSlideTimer; 
end; 

procedure CurPageChanged(CurPageID: Integer); 
begin 
    if CurPageID = wpInstalling then 
    StartSlideTimer 
    else 
    KillSlideTimer; 
end; 

Answer 2

이미지를 변경하기 위해 각 파일 항목에 AfterInstall을 사용하지 않는 이유는 무엇입니까?