Perl 무스 클래스 속성이 아닌 인스턴스 속성 추가

Question

무스 클래스 인스턴스에 속성을 추가해야합니다. 아래 코드에서 Child 클래스의 인스턴스를 만들고 "app"속성을 추가하면 다음 인스턴스를 만들 때이 속성도 추가됩니다. 내가 뭘 잘못했는지, 다시 한번 나는 생성 된 인스턴스마다 속성이 필요하다.

#!C:\perl\bin\perl.exe 
#!/usr/bin/perl 

use v5.10; 
use Moose; 
use Data::Dumper; 

{ 
    package Child; 

    use Moose; 
    use utf8; 

    sub name { 
     say "My name is Richard"; 
    } 
} 

sub add_attribute { 
    my ($object, $attr) = @_; 

    my $meta = $object->meta; 

    if (!$object->can("app")) { 
     $meta->add_attribute(app => (is => 'rw', default => sub{$attr})); 
     $object->app($attr); 
    } 
    else { 
     #$object->app($attr); 
     say "attr $attr already exists: object=". ref($object) . ", attr=".($object->app); 
    } 
} 

my $child = Child->new; 
$child->name; 
add_attribute($child, "First"); 
say "Child Attr: " . $child->app; 
say ""; 
say Dumper($child); 

my $child1 = Child->new; 
$child1->name; 
#add_attribute($child1, "Second"); 
say "Child1 Attr: " . $child1->app; 
say Dumper($child1); 
#say Dumper($child1->meta); 

출력 :

My name is Richard 
Child Attr: First 

$VAR1 = bless({ 
       'app' => 'First' 
       }, 'Child'); 

My name is Richard 
Child1 Attr: First 
$VAR1 = bless({ 
       'app' => 'First' 
       }, 'Child'); 

Answer 1

트릭은, 원래 클래스의 새로운 서브 클래스를 생성하는에 속성을 추가하는 것입니다은, 새로운 서브 클래스로 인스턴스를 rebless. 다음은 그 예입니다.

use v5.14; 

package Person { 
    use Moose; 
    has name => (is => 'ro'); 
} 

sub add_attribute { 
    my ($obj, $name, $value) = @_; 
    my $new_class = Moose::Meta::Class->create_anon_class(
    superclasses => [ ref($obj) ], 
); 
    $new_class->add_attribute($name, is => 'rw'); 
    $new_class->rebless_instance($obj, $name => $value); 
} 

my $alice = Person->new(name => 'Alice'); 
my $bob = Person->new(name => 'Bob'); 

add_attribute($alice, foot_size => 6); 

say $alice->foot_size; 

say $bob->foot_size; # dies, no such method