라이브 스트리밍 플렉스

Question

저는 웹캠에서 Flash Media 서버로 피드를 보내는 Flex 어플리케이션을 작업 중입니다. 응용 프로그램이 서버에 잘 연결되지만 카메라가 Media Server에 아무 것도 보내지 않고 있습니다. 나는 정말로 내 질문에 대한 대답이 정말 간단하다고 확신하지만, 나는 내 코드에서 llok에 또 다른 눈의 집합이 필요하고 내가 뭘 잘못하고 있는지 말해 준다. 도움이 될 것입니다. 대단히 감사합니다. 나는 떠난 머리카락을 조금씩 지켜야 해! 여기에 함수입니다 ... 다시 한 번 감사드립니다.

private function Publisher():void{ 

      var camera1:Camera = Camera.getCamera(); 
      var video:Video = new Video(285, 254); 
      if (camera1) 
      { 
       video.attachCamera(camera1); 
       VideoDisplay1.addChild(video); 
       camera1.addEventListener(ActivityEvent.ACTIVITY, camera_activity); 
       camera1.addEventListener(StatusEvent.STATUS, camera_status); 
      } 

      var nc:NetConnection = new NetConnection(); 
      nc.connect("rtmp://po9nawn4.rtmphost.com/Application"); 
      nc.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler); 

      function netStatusHandler(event:NetStatusEvent):void { 
       switch (event.info.code) { 
        case "NetConnection.Connect.Success": 
         var ns:NetStream = new NetStream(nc); 
         ns.attachCamera(camera1); 
         ns.publish("test", "live"); 
         break; 
        case "NetStream.Play.StreamNotFound": 
         trace("Unable to locate video: "); 
         break; 
       } 
      } 

     } 

Answer 1

시도는 외부 Publisher
을 netStatusHandler을 이동 BTW 당신은 ​​기본 FMS 응용 프로그램에 연결? fms_adminConsole.swf는 클라이언트를 보여줍니까?
UPD :

package { 
/** 
* ... 
* @author www0z0k 
*/ 
    import flash.events.NetStatusEvent; 
    import flash.media.Camera; 
    import flash.media.Video; 
    import flash.net.NetConnection; 
    import flash.net.NetStream; 
    import flash.display.Sprite; 
    [SWF(width='400', height='300', frameRate='30')] 
    public class NewClass extends Sprite { 
    private var vid:Video; 
    private var nc:NetConnection; 
    private var ns:NetStream; 
    private var baseUrl:String = 'rtmp://192.168.1.100/live'; 
    private var appUrl:String = 'stream1'; 
    private var cam:Camera; 
    public function NewClass() { 
     vid = new Video(); 
     addChild(vid); 
     cam = Camera.getCamera(); 
     vid.attachCamera(cam); 
     nc = new NetConnection(); 
     nc.addEventListener(NetStatusEvent.NET_STATUS, onStatus); 
     nc.connect(baseUrl); 
    } 

    private function onStatus(e:NetStatusEvent):void { 
      switch (e.info.code) { 
      case "NetConnection.Connect.Success": 
       ns = new NetStream(nc, NetStream.CONNECT_TO_FMS); 
       ns.attachCamera(cam); 
       ns.addEventListener(NetStatusEvent.NET_STATUS, onStatus); 
       ns.publish(appUrl, 'live'); 
       break; 
      } 
     } 
    } 
} 

완벽하게 작동 내 dev FMS에는