어떻게 StringList.Sort를 Delphi에서 안정적인 정렬로 대체 할 수 있습니까?

Question

나는 간단한 StringList.sort를하고 있지만, Delphi는 안정된 정렬이 아닌 QuickSort를 사용합니다. 즉, 동일한 키를 가진 레코드의 상대적 순서를 변경할 수 있습니다.

안정적인 정렬을 사용해야합니다. 이것을 구현하는 가장 쉬운 방법은 무엇입니까?

---

Mike W의 대답은 너무 많은 코드 변경이 필요없이 가장 간단한 방법 일 수 있습니다.

감사합니다. 마이크.

Answer 1

문자열 목록의 Objects 속성을 아직 사용하고 있지 않다면 객체 속성의 원래 위치를 정수로 저장하는 것이 빠르고 간단합니다. 그런 다음 원래 위치를 고려한 고유 한 안정적인 정렬 비교 함수를 제공 할 수 있습니다. 자신의 코드에서해야 할 일은 CustomSort를 호출하기 전에 개체 목록을 할당하는 전체 목록을 반복하는 것입니다.

function StableSortCompare(List: TStringList; Index1, Index2: Integer): Integer; 
begin 
    result := CompareStr(List[Index1], List[Index2]); 
    if result = 0 then result := integer(List.Objects[Index1]) - integer(List.Objects[Index2]); 
end; 

procedure TSortTestForm.SortButtonClick(Sender: TObject); 
var 
    SL : TStringList; 
    i : integer; 
begin 
    SL := TStringList.Create; 
    try 
    SL.AddObject('One', pointer(0)); 
    SL.AddObject('One', pointer(1)); 
    SL.AddObject('One', pointer(2)); 
    SL.AddObject('Two', pointer(3)); 
    SL.AddObject('Two', pointer(4)); 
    SL.AddObject('One', pointer(5)); 
    SL.AddObject('One', pointer(6)); 
    SL.AddObject('One', pointer(7)); 
    // SL.Sort; // Try instead of custom sort to see difference 
    SL.CustomSort(StableSortCompare); 
    for i := 0 to SL.Count-1 do begin 
     Memo1.Lines.Add(Format('Text: %s Orig Pos: %d', [SL[i], integer(SL.Objects[i])])); 
    end; 
    finally 
    SL.Free; 
    end; 
end;