(TTimer를 사용하지 않고) 프로 시저 내부 회전 TImage의

Question

이 같은 델파이 Firemonkey (베를린)를 사용하여 안드로이드에 다른 정도에서 회전하는 TImage의의이 TButton 절차 내부에 간단한 애니메이션을 만들려고 노력했다 :

procedure TForm1.Button1Click(Sender: TObject); 
begin 
while Image1.RotationAngle < 360 do begin 
Image1.RotationAngle := Image1.RotationAngle+1; 
Image1.Repaint; 
Sleep(1); 
end; 
end; 

을

Image1.Repaint를 사용하거나 사용하지 않고 시도했지만 애니메이션이 작동하지 않지만 TTimer를 사용할 때 완벽하게 작동합니다. 누구든지이 문제를 해결하는 방법을 알고 있습니까?

Answer 1

주 스레드의 모든 Sleep 전화를 사용하지 마십시오, 당신은 너무 TTimer없이 TImage의 회전 수 :

procedure TForm1.Button1Click(Sender: TObject); 
var 
    sText: string; 
begin 
    Button1.Enabled := False; 
    sText := Button1.Text; 
    Button1.Text := 'Wait...'; 
    TThread.CreateAnonymousThread(procedure 
    begin 
    while Image1.RotationAngle < 360 do begin 
     TThread.Synchronize(nil, procedure 
     begin 
     Image1.RotationAngle := Image1.RotationAngle + 2; 
     end); 
     Sleep(10); 
    end; 
    TThread.Synchronize(nil, procedure 
    begin 
     Button1.Text := sText; 
     Button1.Enabled := True; 
    end); 
    end).Start; 
end; 

두 번째 솔루션 : 양식에 Anim: TFloatAnimation을 추가

type 
    TForm1 = class(TForm) 
    ... 
    public 
    Anim: TFloatAnimation; 
    end; 

var 
    Form1: TForm1; 

implementation 

{$R *.fmx} 

procedure TForm1.Button1Click(Sender: TObject); 
begin 
    Anim.Enabled := False; 
    Image1.RotationAngle := 0; 
    Anim.Enabled := True; 
end; 

procedure TForm1.FormCreate(Sender: TObject); 
begin 
    Anim := TFloatAnimation.Create(Self); 
    Anim.Parent := Self; 
    Anim.Duration := 1; 
    Anim.StartValue := 0; 
    Anim.StopValue := 360; 
    Anim.PropertyName := 'Image1.RotationAngle'; 
end; 

Answer 2

가 FMX를 추가합니다. uses 절을 사용하고 button onlick 이벤트에서 TAnimator를 사용하십시오.

procedure TForm1.Button1Click(Sender: TObject); 
begin 
Image1.RotationAngle:=0; 
TAnimator.AnimateFloat(Image1,'RotationAngle',360,1,TAnimationType.InOut, TInterpolationType.Exponential); 
end; 

AnimateFloat, AnimateFloatWait, AnimateFloatDelay에 대한 자세한 내용은 문서를 참조하십시오.