Pseudcript의 프롬프트 Monad

Question

나는 Prompt의 정의를 통해 작업 중이며 Bind 인스턴스는 here으로 설명되어 있으며 Purescript에서 어떻게 보이는지 알아 내려고했습니다.

실존 유형에 Purescript.Exists을 사용하고 있습니다. 내 (고화질)은 다음과 같습니다 runExists 작업 할 때

나는 특히 Bind 인스턴스에서 Ask 케이스를 쓰기에 부착하고

data PromptAskF p r a 
    = PromptAskF (p a) (a -> Prompt p r) 

type PromptAsk p r = Exists (PromptAskF p r) 

data Prompt p r 
    = Ask (PromptAsk p r) 
    | Answer r 

instance bindPrompt :: Bind (Prompt p) where 
    bind (Answer x) k = k x 
    bind (Ask ask) k = ??? 

, 나는 유형에 대한 매우 혼란 스러워요.

이 인스턴스는 어떻게 작성해야합니까?

감사합니다, 트릭을해야이 같은

마이클

Answer 1

뭔가 :

data PromptAskF p r a 
    = PromptAskF (p a) (a -> Prompt p r) 

type PromptAsk p r = Exists (PromptAskF p r) 

mapPA 
    :: forall p r r' 
    . (forall a. (a -> Prompt p r) -> (a -> Prompt p r')) 
    -> PromptAsk p r 
    -> PromptAsk p r' 
mapPA f = runExists \(PromptAskF req cont) -> mkExists $ PromptAskF req (f cont) 

data Prompt p r 
    = Ask (PromptAsk p r) 
    | Answer r 

instance functorPrompt :: Functor (Prompt p) where 
    map f (Answer r) = Answer (f r) 
    map f (Ask ask) = Ask $ mapPA (map (map f)) ask 

instance applyPrompt :: Apply (Prompt p) where 
    apply = ap 

instance applicativePrompt :: Applicative (Prompt p) where 
    pure = Answer 

instance bindPrompt :: Bind (Prompt p) where 
    bind (Answer x) k = k x 
    bind (Ask ask) k = Ask $ mapPA (\cont ans -> cont ans >>= k) ask 

instance monadPrompt :: Monad (Prompt p) 

mapPA 기능은 반복적으로 runExists/mkExists하지 않고 PromptAskF 계속 업데이트를위한 편의이다.