내 MS 액세스 양식에서 VBA 코드 아래 내가 가진

Question

MS-Access에서 하위에 함수의 변수를 사용할 수 없습니다 내 Load() 하위에 GetUserName를 사용하여 값을 얻을 수 있지만, 드릴 수 없습니다

Option Compare Database 
Option Explicit 

Public Function GetUserName() As String 
    Dim obj1 As Object 
    Dim GetEmpID As String 
    Set obj1 = CreateObject("WScript.Network") 
    GetUserName = DLookup("[BAFUser]", "BAF_User", "[BRID] = '" & obj1.UserName & "'") 
    GetEmpID = DLookup("[EmpID]", "BAF_User", "[BRID] = '" & obj1.UserName & "'") 
    Set obj1 = Nothing 
End Function 

Private Sub Form_Load() 
    Me.EmpName.Value = GetUserName 
    Me.EmpID.Value = GetEmpID 
End Sub 

GetEmpID을 사용하여 값을 가져옵니다.

가능한 이유는 무엇입니까? 어떻게 해결할 수 있습니까?

미리 감사드립니다.

Answer 1

옵션 1 (그 값을 반환하지 않기 때문에, 현재 서브)는 기능 설정 모듈 수준 변수를 생성

Option Compare Database 
Option Explicit 

Dim UserName as String 
Dim EmpID as String 

Public Sub GetValues() 
    Dim obj1 As Object 

    Set obj1 = CreateObject("WScript.Network") 
    UserName = DLookup("[BAFUser]", "BAF_User", "[BRID] = '" & obj1.UserName & "'") 
    EmpID = DLookup("[EmpID]", "BAF_User", "[BRID] = '" & obj1.UserName & "'") 
    Set obj1 = Nothing 
End Sub 

Private Sub Form_Load() 
    Call GetValues() 'Invoke the function to set values 
    Me.EmpName.Value = UserName 'retrieve values from module level variables 
    Me.EmpID.Value = EmpID 
End Sub 

옵션 2 : 변수하는 ByRef 만든다.

Option Compare Database 
Option Explicit 

Public Sub GetValues(ByRef UserName as String, ByRef EmpID as String) 
    Dim obj1 As Object 

    Set obj1 = CreateObject("WScript.Network") 
    UserName = DLookup("[BAFUser]", "BAF_User", "[BRID] = '" & obj1.UserName & "'") 
    EmpID = DLookup("[EmpID]", "BAF_User", "[BRID] = '" & obj1.UserName & "'") 
    Set obj1 = Nothing 
End Sub 

Private Sub Form_Load() 
    Dim UserName as String 
    Dim EmpID as String 
    Call GetValues(UserName, EmpId) 'Invoke the function to set values of local variables. 
    Me.EmpName.Value = UserName 'retrieve values from function scoped variables. 
    Me.EmpID.Value = EmpID 
End Sub 

경고 : 메모리에서 입력. 사소한 수정이 필요할 수 있습니다.

Answer 2

항상 함수에서 ByRef를 사용할 수 있습니다.

Option Compare Database 
Option Explicit 

Public Function GetUserName(ByRef GetEmpID as string) as string 
dim obj1 as object 

Set obj1 = CreateObject("WScript.Network") 

GetUserName = DLookup("[BAFUser]", "BAF_User", "[BRID] = '" & obj1.UserName & "'") 
GetEmpID = DLookup("[EmpID]", "BAF_User", "[BRID] = '" & obj1.UserName & "'") 

If not obj1 is nothing then 
    Set obj1 = Nothing 
End If 
End Function 

Private Sub Form_Load() 
Dim GetEmpID as string 

GetEmpID = "None" 

Me.EmpName.value = GetUserName(GetEmpID) 
Me.EmpID.Value = GetEmpID 
End Sub 

ByRef는 메모리에 변수를 저장하는 데 사용되는 주소를 전달합니다. 값 대신 주소가 전달되면 주소에 발생한 모든 변경 사항이 프로젝트의 변수에 적용됩니다.

ByVal로와하는 ByRef의 자세한 설명은 아래 웹 사이트를 참조하십시오 http://www.cpearson.com/excel/byrefbyval.aspx