실시간 백틱 출력 처리

Question

이것이 가능한지 모르겠지만 소켓을 통한 명령 출력을 보내려고하므로 명령이 실행되는 동안 클라이언트와 서버 컴퓨터 모두에 표시됩니다. 백틱을 사용하려고하면 오랜 시간이 걸리는 명령을 실행할 때 명령이 완료 될 때까지 출력이 변수에 저장되지 않습니다.

질문 : 다른 프로세스를 생성하고 변수를 "감시"한다고 말하면 라인별로 출력을 검사하는 방법이 있습니까?

편집 :이 내가 출력 명령이 완료되기 전에 표시하고자하는 개방

open DATA, "pause |" or die "Failed: $!"; 
while(defined(my $line = <DATA>)){ 
    chomp($line); 
    print "$line\n"; 
} 

으로 시도하는 것이다.

Answer 1

당신은 올바른 접근 방식을 가지고 있습니다. STDOUT 터미널 ("광고 버퍼링") 인 경우 개행 만나면

my @cmd = ('perl', '-e', '$|=1; for (1..5) { print "$_\n"; sleep 1; }'); 

open(my $pipe, '-|', @cmd) 
    or die("Can't launch child: $!\n"); 

while (defined(my $line = <$pipe>)) { 
    chomp($line); 
    print "<$line>\n"; 
} 

STDOUT 서면, 대부분의 프로그램들은 출력 플러시. STDOUT이 터미널이 아닌 경우 ("블록 버퍼링") 대부분의 프로그램은 4KiB 또는 8KiB의 청크 출력을 차단합니다. 그래서 위의 예에서 하위 프로그램에 $|=1;을 사용해야했습니다.

설명대로 작동하는 프로그램은 파이프 대신 의사 터미널을 사용하여 회선 버퍼링을 사용하여 속일 수 있습니다.

my @cmd = ('unbuffer', 'perl', '-e', 'for (1..5) { print "$_\n"; sleep 1; }'); 

open(my $pipe, '-|', @cmd) 
    or die("Can't launch child: $!\n"); 

while (defined(my $line = <$pipe>)) { 
    chomp($line); 
    print "<$line>\n"; 
} 

IPC::Run은 가상 터미널을 생성하는 고유 한 방법을 제공합니다.

use IPC::Run qw(run); 

my @cmd = ('perl', '-e', 'for (1..5) { print "$_\n"; sleep 1; }'); 

my $buf = ''; 
run(\@cmd, '>pty>', sub { 
    $buf .= $_[0]; 
    while ($buf =~ s/^(.*)\r\n//) { 
     print "<$1>\n"; 
    } 
});