DBMS_OUTPUT.GET_LINES를 VARCHAR2로 변환하는 방법은 무엇입니까?

Question

DBMS_OUTPUT.CHARARR의 결과를 제공하는 DBMS_OUTPUT.GET_LINES를 사용할 때이를 varchar2로 변환하는 방법은 무엇입니까? DBMS_OUTPUT.GET_LINES를 사용하여 모든 DBMS_PUTLINE 문을 가져 와서 호출 프로그램에 문자열로 반환하려고합니다.

데이터베이스 : 오라클 12C

PLSQL 버전 : 버전 11.0.6.1776

declare 
    -- Non-scalar parameters require additional processing 

    v_Data  DBMS_OUTPUT.CHARARR; 
    v_NumLines NUMBER; 
begin 
    -- Call the procedure 


    -- Procedure that will generate DMBS_OUTPUT.PUT_LINEs 
    executeProcFoo(); 

    v_NumLines := 1000; 
    DBMS_OUTPUT.GET_LINES(v_Data, v_NumLines); 

    FOR v_Counter IN 1..v_NumLines LOOP 
     --output putlines from get_lines 
     DBMS_OUTPUT.put_line(v_Data(v_Counter)); 
    END LOOP; 
end; 

Answer 1

이 시도 : 당신은 어떤 프로시 저나 함수에 v_var 다음 전달할 수 있습니다

DECLARE 
    -- Non-scalar parameters require additional processing 

    v_Data  DBMS_OUTPUT.CHARARR; 
    v_NumLines NUMBER; 

    TYPE v IS TABLE OF VARCHAR2 (1000) 
       INDEX BY BINARY_INTEGER; 

    v_var  v; 
BEGIN 
    -- Call the procedure 


    -- Procedure that will generate DMBS_OUTPUT.PUT_LINEs 
    DBMS_OUTPUT.PUT_LINE ('vvvv'); 
    DBMS_OUTPUT.put_line ('xxxxx'); 

    v_NumLines := 1000; 
    DBMS_OUTPUT.GET_LINES (v_Data, v_NumLines); 

    FOR v_Counter IN v_data.FIRST .. v_data.LAST 
    LOOP 
     --output putlines from get_lines 
     DBMS_OUTPUT.put_line (v_Data (v_Counter)); 
     v_var (v_counter) := v_data (v_counter); 
    END LOOP; 
END; 

.

Answer 2

주석에서 Java 애플리케이션에 DBMS_OUTPUT 버퍼를 가져 오는 편리한 방법을 찾고있는 것처럼 보입니다. SQL 형식을 Java 호환 배열로 게시하는 방법이 있지만 (저는 Java 개발자가 아니므로 dbms_output.get_lines에 오버로드가 발생하여 dbmsoutput_linesarray을 반환 할 수 있습니다.이 경우 더 쉽게 작업 할 수 있습니다. dbms_output.chararray), 참조 커서가 트릭을 할 수 있다고 생각났습니다.

그래서, 당신은 컬렉션으로 출력 버퍼를 반환하는 함수를 만들 수 있습니다 경우

create or replace function get_dbms_output 
    return dbmsoutput_linesarray 
as 
    l_output dbmsoutput_linesarray; 
    l_linecount number; 
begin 
    dbms_output.get_lines(l_output, l_linecount); 

    if l_output.count > l_linecount then 
     -- Remove the final empty line above l_linecount 
     l_output.trim; 
    end if; 

    return l_output; 
end get_dbms_output; 

지금 당신에게 표준을 제공한다

select column_value from table(get_dbms_output) 

등 정상적인 SQL 쿼리를 실행할 수 있습니다 참조 커서.

데모 :

SQL> set serveroutput off 
SQL> 
SQL> begin 
    2  dbms_output.enable; 
    3  dbms_output.put_line('This is a line'); 
    4  dbms_output.put_line('This is another line'); 
    5  dbms_output.put_line('This is the last line.'); 
    6 end; 
    7/

PL/SQL procedure successfully completed. 

SQL> select column_value from table(get_dbms_output); 

COLUMN_VALUE 
-------------------------------------------------------- 
This is a line 
This is another line 
This is the last line. 

3 rows selected. 

합니다 (set serveroutput off은 * SQL을 중지하는 것입니다 플러스 전화의 끝에서 dbms_output.get_lines 자신의 일을하고 할 수있는 아무것도 내 기능을 떠나는에서 dbms_output.enable는 set serveroutput off가 DBMS_OUTPUT을 비활성화하기 때문이다. 이것은 SQL * Plus의 데모 용도로만 사용되며 자바에서는 필요하지 않습니다.