정적 메서드를 사용하여 인터페이스를 구현할 수 있습니까?

Question

다음은 컴파일되지 않지만 가능한 것입니까?

IDefaultHelp = interface 
    ['{6997FC42-7481-4CDA-940A-0351071266C7}'] 
    function GetTemplate: TXMLDocument; 

    end; 

    TDefaultHelp = class(TInterfacedObject, INodeHelp) 
    class function GetTemplate: TXMLDocument; static; <<-- error 
    end; 

구현 개체를 인스턴스화 할 필요가 없습니다.

Create 실제 클래스를 사용하지 않고 인터페이스를 구현할 수있는 방법이 있습니까?

Answer 1

필자는 인스턴스를 인스턴스화하지 않아도되는지 실제로 인정하지 않습니다. 이제 정적 클래스 메서드를 사용하여 인터페이스를 구현할 수 없습니다. 원하는 경우 정적 클래스 메서드에 위임하여 인터페이스를 구현할 수 있습니다.

구현 개체를 인스턴스화 할 필요가 없습니다.

그래서, 객체를 생성 할 필요없이 인터페이스를 구현하는 욕망으로 질문을 가지고, 당신은 Generics.Defaults 장치에서 비교 자 인터페이스의 방식으로 구현 된 일정의 vtable을 사용할 수 있습니다. 예를 들어

:

unit Unit1; 

interface 

uses 
    Xml.XMLDoc; 

type 
    IDefaultHelp = interface 
    ['{6997FC42-7481-4CDA-940A-0351071266C7}'] 
    function GetTemplate: IXMLDocument; 
    end; 

function GetDefaultHelp: IDefaultHelp; 

implementation 

function NopAddref(inst: Pointer): Integer; stdcall; 
begin 
    Result := -1; 
end; 

function NopRelease(inst: Pointer): Integer; stdcall; 
begin 
    Result := -1; 
end; 

function NopQueryInterface(inst: Pointer; const IID: TGUID; out Obj): HResult; 
    stdcall; 
begin 
    Result := E_NOINTERFACE; 
end; 

function GetTemplate(inst: Pointer): IXMLDocument; 
begin 
    Result := TXMLDocument.Create(nil); 
end; 

const 
    DefaultHelp_Vtable: array[0..3] of Pointer = 
    (
    @NopQueryInterface, 
    @NopAddref, 
    @NopRelease, 
    @GetTemplate 
); 
    DefaultHelp_Instance: Pointer = @DefaultHelp_Vtable; 

function GetDefaultHelp: IDefaultHelp; 
begin 
    Result := IDefaultHelp(@DefaultHelp_Instance); 
end; 

end.