xtend 프로젝트에서 xtend로 코드 생성

Question

xtext 프로젝트에서 작업 중이며 .xtext 파일을 통해 오브젝트를 생성 중입니다. 생성 된 개체 중 하나에 새 특성을 추가하려고합니다. http://christiandietrich.wordpress.com/2011/07/22/customizing-xtext-metamodel-inference-using-xtend2/ 다음 코드는 ObjectValue 에 임시 변수를 생성하지만 temp는 MyObject 유형이어야합니다.

어떻게 그렇게합니까? 그것에 대해 읽을 수있는 곳은 어디입니까? 우선

import org.eclipse.emf.codegen.ecore.genmodel.GenModelPackage 
import org.eclipse.emf.common.util.BasicEMap$Entry 
import org.eclipse.emf.ecore.EClass 
import org.eclipse.emf.ecore.EPackage 
import org.eclipse.emf.ecore.EcoreFactory 
import org.eclipse.emf.ecore.EcorePackage 
import org.eclipse.xtext.GeneratedMetamodel 
import org.eclipse.xtext.xtext.ecoreInference.IXtext2EcorePostProcessor 

class CodeGeneratorClass implements IXtext2EcorePostProcessor { 

    override process(GeneratedMetamodel metamodel) { 
     metamodel.EPackage.process 
    } 

    def process(EPackage p) { 
     for (c : p.EClassifiers.filter(typeof(EClass))) { 
      if (c.name == "ObjectValue") { 
       c.handle 
      } 
     } 
    } 

    def handle (EClass c) { 
    val attr = EcoreFactory::eINSTANCE.createEAttribute 
    attr.name = "temp" 
    attr.EType = EcorePackage::eINSTANCE.EString 
    c.EStructuralFeatures += attr 
} 
} 

Answer 1

: MyObject는 EClass 또는 EDataType 의해 어느 설명한다. 일반 Java 객체는이를 수행하지 않습니다.

MyObject이 EDataType 인 경우 handle 방법에 EAttribute을 추가해야합니다. 귀하의 handle 방법은 거의 바로 만 EType 조정해야한다 :

attr.EType = MyPackage::eINSTANCE.MyObject 

그렇지 않으면 : MyObject는 EClass의 경우, 당신은 대신 EAttribute의 EReference를 추가해야합니다. 이 경우의 handle 방법은 다음과 같습니다

def handleReference(EClass c){ 
    val ref = EcoreFactory::eINSTANCE.createEReference 
    ref.name = "temp" 
    ref.EType = MyPackage::eINSTANCE.MyObject 
    c.EStructuralFeatures += ref 
} 

편집

새로운, 최소한의 EDataType을 정의하고 모델로를 연결하기 위해 다음 코드는 작동합니다 :

def void process(GeneratedMetamodel it){ 
    // create new dynamic EDataType 
    val dataType = EcoreFactory::eINSTANCE.createEDataType => [ 
     name = 'MyObject' 
     instanceTypeName = 'java.package.with.MyObject' 
    ] 

    // register new EDataType in own model package 
    EPackage.EClassifiers += dataType 

    // attach as EAttribute to appropriate EClasses 
    EPackage.EClassifiers.filter(typeof(EClass)).filter[name == 'ObjectValue'].forEach[ 
     EStructuralFeatures += EcoreFactory::eINSTANCE.createEAttribute => [ 
      name = "temp" 
      EType = dataType 
     ] 
    ] 
}