XSLT : 조회 테이블에서 데이터를 삽입하려면 어떻게해야합니까?

Question

한 XML 문서의 ID를 조회 XML 문서와 일치시키고 일치하는 노드에 포함 된 값을 대체하여 속성에 값을 삽입하려고합니다. 내가 정확하게 일치를 만들고 평가할 수 있지만 일치하는 노드의 값을 결과 XML에 삽입하는 방법을 알 수 없습니다. 구체적으로 말하자면, 현재 단어 번호의 값을 가져오고, 이전의 번호 매기기 시스템과 일치하는 값 목록에서 일치하는 ID를 찾아 결합 된 XML 문서 출력의 특성으로 해당 값을 삽입하려고합니다. 일치하는 항목이 없으면 현재 NO 필드를 입력합니다.

lookup.xml :

<?xml version="1.0" encoding="ISO-8859-1"?> 
<mdict> 
    <PR id="NEW1">OLD1</PR> 
    <PR id="NEW2">OLD2</PR> 
    <PR id="NEW3">OLD3</PR> 
    <PR id="NEW4">OLD4</PR> 
    <PR id="NEW5">OLD5</PR> 
    <PR id="NEW6">OLD6</PR> 

</mdict> 

XML :

<?xml version = "1.0" encoding = "UTF-8"?> 
<dictionary> 
    <entry><NO>NEW1</NO><PR>phon text1</PR></entry> 
    <entry><NO>NEW2</NO><PR>phon text2</PR></entry> 
    <entry><NO>NEW3</NO><PR>phon text3</PR></entry> 
    <entry><NO>NEW4</NO><PR>phon text4</PR></entry> 
    <entry><NO>NEW5</NO><PR>phon text5</PR></entry> 
    <entry><NO>NEW6</NO><PR>phon text6</PR></entry> 
</dictionary> 

XSLT :

?xml version="1.0" encoding="UTF-8"?> 
<xsl:transform 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0"> 
    <xsl:output method="xml" encoding="utf-8" indent="no"/> 

    <xsl:variable name='prons' select='document("lookup.xml")'/> 
    <xsl:key name='pron' match='PR' use='@id' /> 

    <xsl:template match="@*|node()"> 
     <xsl:copy> 
      <xsl:apply-templates select="@*|node()" /> 
     </xsl:copy> 
    </xsl:template> 

    <xsl:template match="PR"> 
     <xsl:param name="curr-pron"/> 
      <xsl:choose> 
       <xsl:when test="../preceding-sibling::NO/text() = $prons/mdict/PR/@id"> 
        <xsl:value-of select="key('pron', $curr-pron)/PR"/> 
        <pr pron="{$curr-pron}"><xsl:apply-templates/></pr> 
       </xsl:when> 
       <xsl:otherwise> 
        <pr pron="{../preceding-sibling::NO}"><xsl:apply-templates/></pr> 
        </xsl:otherwise> 
       </xsl:choose> 
    </xsl:template> 

원하는 출력 :

<dictionary> 
    <entry><NO>NEW1</NO><pr pron="OLD1">phon text1</pr></entry> 
    <entry><NO>NEW2</NO><pr pron="OLD2">phon text2</pr></entry> 
    <entry><NO>NEW3</NO><pr pron="OLD3">phon text3</pr></entry> 
    <entry><NO>NEW4</NO><pr pron="OLD4">phon text4</pr></entry> 
    <entry><NO>NEW5</NO><pr pron="OLD5">phon text5</pr></entry> 
    <entry><NO>NEW6</NO><pr pron="OLD6">phon text6</pr></entry> 
</dictionary> 

,536,

감사합니다.

Answer 1

난 당신이이 방법을 시도 좋을 것 :

XSLT 이것은 위의 XML 문서를 처리하는 가정 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/> 
<xsl:strip-space elements="*"/> 

<xsl:key name="old-pron" match="PR" use="@id" /> 

<!-- identity transform --> 
<xsl:template match="@*|node()"> 
    <xsl:copy> 
     <xsl:apply-templates select="@*|node()"/> 
    </xsl:copy> 
</xsl:template> 

<xsl:template match="PR"> 
    <xsl:variable name="id" select="../NO" /> 
    <pr> 
     <xsl:attribute name="pron"> 
     <!-- switch context to use key --> 
      <xsl:for-each select="document('lookup.xml')"> 
       <xsl:value-of select="key('old-pron', $id)"/> 
      </xsl:for-each> 
     </xsl:attribute> 
     <xsl:apply-templates/> 
    </pr> 
</xsl:template> 

</xsl:stylesheet> 

.

XSLT 1.0에서는 문서간에 키가 작동하지 않습니다.