NullSoft 자동 설치 중에 여유 공간을 확인하려면 어떻게합니까?

Question

자동 설치 모드에서는 PageEx directory으로 설치 대상을 묻지 않으므로 DirVerify 및 GetInstDirError 기능이 호출되지 않습니다.

위의 이유와 동일한 이유로 설치 대상을 하드 코딩하는 설치에도 적용 할 수 있습니다. PageEx directory은 호출되지 않습니다.

Answer 1

샘플 코드를 확인하지만, Win9x의 경우에 호출 $ {디스크 공간 늘림} 실패 할 수 있습니다 :

는 여기 샘플 설치에 있습니다. 나는 또한 지정의 필요성을 제거 섹션 ID의

!define APPNAME "CalcEnoughSpace" 
name "${APPNAME}" 
outfile "$%temp%\${APPNAME}.exe" 
ShowInstDetails show 
RequestExecutionLevel user 
installdir "$Temp" 
AllowRootDirInstall true 

!include Sections.nsh 
!include LogicLib.nsh 

Function .onInit 
push $instdir 
call VerifyFreeSpace 
pop $0 
${If} $0 < 1 
    MessageBox mb_iconstop "Not enough free space!" 
${EndIf} 
FunctionEnd 

page instfiles 

Section !a 
AddSize 10000 
SectionEnd 
Section /o b 
AddSize 10000 
SectionEnd 

SectionGroup grp 
Section c 
AddSize 10000 
SectionEnd 
SectionGroupEnd 



Function VerifyFreeSpace 
System::Store s 
pop $0 ;path to check 
Push 0 ;default to no 
System::Call 'kernel32::GetDiskFreeSpaceEx(tr0,*l.r1,*l,*l)i.r2' 
${If} $2 < 1 
    StrCpy $0 $0 3 
    System::Call 'kernel32::GetDiskFreeSpace(tr0,*i.r1,*i.r2,*i.r3,*i)i.r4' 
    IntCmpU $4 0 ret 
    IntOp $1 $1 * $2 
    System::Int64Op $1 * $3 
    pop $1 
${EndIf} 
System::Int64Op $1/1024 ;to kb 
pop $1 
StrCpy $4 0 ;size 
StrCpy $2 0 ;section idx 
loop: 
    ClearErrors 
    SectionGetFlags $2 $3 
    IfErrors testspace 
    IntOp $3 $3 & ${SF_SELECTED} 
    ${If} $3 <> 0 
     SectionGetSize $2 $3 
     IntOp $4 $4 + $3 
     ${EndIf} 
    IntOp $2 $2 + 1 
    goto loop 
testspace: 
pop $2 ;throw away default return value 
System::Int64Op $1 > $4 
ret: 
System::Store l 
FunctionEnd 

난 단지, 잘하면 더 버그 :

Answer 2

이렇게하려면 NSIS에 CheckFreeSpace이라는 함수를 작성했습니다. 불행하게도 그것은 다음과 같은 제한이 있습니다

• 이 설치에서 모든 섹션의 크기를 계산하려면 각 섹션 ID가에 기록 된 각 변수를 알고에 의해, 각 섹션을 추가 CheckFreeSpace을 수정해야합니다. NSIS를 사용하여 설치 될 모든 섹션을 반복하는 방법을 찾을 수 없습니다.
• ${DriveSpace}에 임의의 디렉터리 경로가 아닌 드라이브 문자가 필요하므로 설치 드라이브를 계산해야합니다. 드라이브 문자 문자열은 StrCpy $instdrive $INSTDIR 3으로 계산됩니다. $INSTDIR 변수가 상대 경로이거나 C:\과 같은 문자열로 시작하지 않으면이 작업은 실패합니다.
• 설치를 계속할 수없는 경우 MessageBox가 생성됩니다. 성명 끝에 /SD IDOK을 추가하여 MessageBox을 표시하지 않을 수 있지만 설치 실패를 사용자에게 알리지는 않습니다. NSIS에서 stdout (으)로 방출 할 수있는 방법을 찾을 수 없습니다. 아마도 설치 프로그램의 반환 코드로 충분할까요?
• 디스크 여유 공간이 매우 부족한 경우 (예 : 10KB) 설치 프로그램이 전혀 실행되지 않습니다. 임시 DLL을 \tmp 디렉토리에 압축을 푸는 공간이 없습니다.

아래의 구현에서 CheckFreeSpace은 설치 후 여유 공간에 대한 하드 코드 된 값을가집니다. 분명히 그것은 매개 변수화 될 수 있습니다.

!include FileFunc.nsh 
!insertmacro DriveSpace 

Name "CheckFreeSpace" 
OutFile "C:\CheckFreeSpace.exe" 

InstallDir C:\tmp\checkfreespace 

Page instfiles 

Section "install_section" install_section_id 
    Call CheckFreeSpace 

    CreateDirectory $INSTDIR 
    SetOutPath $INSTDIR 
    File "C:\installme.bat" 

    WriteUninstaller "$INSTDIR\Uninstall.exe" 

    DetailPrint "Installation Successful." 
SectionEnd 

Section "Uninstall" 

    RMDIR /r "$INSTDIR" 

SectionEnd 

Function CheckFreeSpace 

    var /GLOBAL installsize 
    var /GLOBAL adjustedinstallsize 
    var /GLOBAL freespace 
    var /GLOBAL instdrive 

    ; Verify that we have sufficient space for the install 

    ; SectionGetSize returns the size of each section in kilobyte. 
    SectionGetSize ${install_section_id} $installsize 

    ; Adjust the required install size by 10mb, as a minimum amount 
    ; of free space left after installation. 
    IntOp $adjustedinstallsize $installsize + 10240 

    ; Compute the drive that is the installation target; the 
    ; ${DriveSpace} macro will not accept a path, it must be a drive. 
    StrCpy $instdrive $INSTDIR 3 

    ; Compute drive space free in kilobyte 
    ${DriveSpace} $instdrive "/D=F /S=K" $freespace 

    DetailPrint "Determined installer needs $adjustedinstallsize kb ($installsize kb) while $freespace kb is free" 

    IntCmp $adjustedinstallsize $freespace spaceok spaceok 

    MessageBox MB_OK|MB_ICONSTOP "Insufficient space for installation. Please free space for installation directory $INSTDIR and try again." 
    DetailPrint "Insufficient space for installation. Installer needs $adjustedinstallsize kb, but freespace is only $freespace kb." 
    Abort "Insufficient space for installation." 

    spaceok: 
    DetailPrint "Installation target space is sufficient" 

FunctionEnd 

Answer 3

당신이 침묵에 대한 샘플 스크립트가 설치 한 마십시오 제한된 테스트를 존재하지 않았다?