VBScript WQL 정렬 결과 집합?

Question

분명히 WQL에 ORDER BY 절이 없습니다. 열 중 하나를 기반으로 결과 집합을 정렬하는 방법이 있습니까? 예를 들어 :

Set objWMIService = GetObject("winmgmts:{impersonationLevel=impersonate}!\\.\root\cimv2") 
sSQL = "Select Time,Source,Event,CategoryNum,Category,TypeNum,Type,User,ComputerName,Insertion1,Insertion2,Data from Win32_NTLogEvent Where Logfile = 'System' and SourceName = 'Service Control Manager'" 
Set resultSet = objWMIService.ExecQuery (sSQL) 
For Each objEvent In resultSet 
    ... 
Next 

는 Time 열을 기준으로 resultSet을 정렬 할 수있는 방법이 있습니까?

Answer 1

WQL 실제로 순서 지정 절이 없으므로 쿼리에서 직접 정렬 할 수 없습니다. 당신이 할 수는 disconnected recordset에서 반환 된 데이터를 입력 한 다음 레코드 분류되어 필요에 따라

Set DataList = CreateObject("ADOR.Recordset") 
DataList.Fields.Append "Time", 7 
DataList.Fields.Append "Source", 200, 255 
DataList.Fields.Append "Event", 3 
... 
DataList.Open 

Set wmi = GetObject("winmgmts:{impersonationLevel=impersonate}!//./root/cimv2") 
qry = "SELECT Time,Source,Event,CategoryNum,Category,TypeNum,Type,User,ComputerName,Insertion1,Insertion2,Data " & _ 
     "FROM Win32_NTLogEvent " & _ 
     "WHERE Logfile='System' AND SourceName='Service Control Manager'" 

For Each evt In wmi.ExecQuery(qry) 
    DataList.AddNew 
    DataList("Time") = evt.Time 
    DataList("Source") = evt.Source 
    DataList("Event") = evt.Event 
    ... 
    DataList.Update 
Next 

DataList.Sort = "Time" 
DataList.MoveFirst 
Do Until DataList.EOF 
    WScript.Echo DataList.Fields.Item("Time") & vbTab & _ 
     DataList.Fields.Item("Event") 
    DataList.MoveNext 
Loop 

이 필드의 data type를 조정합니다.