익명 프로 시저에서 로컬 변수를 처리하면 TThread.Queue로 전달됩니다.

Question

일부 작업을 수행하는 스레드를 사용하는 프로그램이 있습니다. 스레드는 다른 스레드 (이 예제에서는 주 스레드)에 진행 상황을 알려야합니다.

동기화를 수행하려면()을 동기화하면 모든 것이 예상대로 작동합니다. 내가 메인 스레드와 동기화와에 대한 변수를 게시 목록에 넣어 경우 모든 단일 값의 제대로 내 목록 상자에 인쇄를 얻을 :

procedure TWorkerThread.Execute; 
var 
    i: Integer; 
begin 
    inherited; 

    for i := 1 to 1000 do 
    begin 
    Synchronize(
     procedure() 
     begin 
     FireEvent(i); 
     end); 
    end; 
end; 

출력 : 1, 2, 3, 4, 5. .. 1000

I 사용할 경우 큐()의 출력이 예상과 동기화 수행 할 수

procedure TWorkerThread.Execute; 
var 
    i: Integer; 
begin 
    inherited; 

    for i := 1 to 1000 do 
    begin 
    Queue(
     procedure() 
     begin 
     FireEvent(i); 
     end); 
    end; 
end; 

,617을

출력 : 200, 339, 562, 934, 1001, 1001, 1001, 1001, 1001, 1001, 1001, 1001, 1001, [...]

여기 무슨 일 이죠? 내 이해에서 익명 프로 시저가 변수 "i"를 캡처해야합니까?

Answer 1

익명 프로시 저는 변수 참조를 캡처합니다. 이것은 익명 프로 시저가 실행될 때 값이 결정되지 않음을 의미합니다.

값을 포착하기 위해,이 같은 독특한 프레임으로 포장해야합니다 :

Type 
    TWorkerThread = class (TThread) 
    ... 
    function GetEventProc(ix : Integer): TThreadProcedure; 
    end; 

function TWorkerThread.GetEventProc(ix : Integer) : TThreadProcedure; 
// Each time this function is called, a new frame capturing ix 
// (and its current value) will be produced. 
begin 
    Result := procedure begin FireEvent(ix); end; 
end; 

procedure TWorkerThread.Execute; 
var 
    i: Integer; 
begin 
    inherited; 

    for i := 1 to 1000 do 
    begin 
    Queue(GetEventProc(i)); 
    end; 
end; 

도 Anonymous methods - variable capture versus value capture를 참조하십시오.