fortran을 사용하여 함수를 서브 루틴으로 전달합니다.

Question

나는 일련의 서브 루틴을 작성하여 라이브러리로 컴파일했다. 이 서브 루틴은 정의 된 함수 (x, y)를 기반으로합니다. 현재이 라이브러리 루틴 내부에 묻혀 있습니다. 그러나이 라이브러리에 어떤 함수 (x, y)도 전달할 수 있어야합니다. 가능합니까? 고마워요!

Answer 1

module ExampleFuncs 

    implicit none 

abstract interface 
    function func (z) 
     real :: func 
     real, intent (in) :: z 
    end function func 
end interface 


contains 


subroutine EvalFunc (aFunc_ptr, x) 

    procedure (func), pointer :: aFunc_ptr 
    real, intent (in) :: x 

    write (*, *) "answer:", aFunc_ptr (x) 

end subroutine EvalFunc 


function f1 (x) 
    real :: f1 
    real, intent (in) :: x 

    f1 = 2.0 * x 

end function f1 


function f2 (x) 
    real :: f2 
    real, intent (in) :: x 

    f2 = 3.0 * x**2 

end function f2 

end module ExampleFuncs 


program Func_to_Sub 

    use ExampleFuncs 

    implicit none 

    procedure (func), pointer :: f_ptr => null() 

    f_ptr => f1 
    call EvalFunc (f_ptr, 2.0) 

    f_ptr => f2 
    call EvalFunc (f_ptr, 2.0) 

    stop 

end program Func_to_Sub