이 Java 코드를 Scheme으로 번역하면 도움이 될 것입니다.

Question

Scheme을 배우고 있으며 기본 사항을 읽었지만 Java 클래스를 Scheme 코드에 "매핑"하는 방법을 여전히 이해할 수 없습니다. 너희들이 여기서 나를 도울 수 있니? 은 "관용적 내가 너무 많은 숙제처럼 보이는 무언가를 대답하지 않았을

public class sumFibonacciValues { 
    public static void main(String [] args) { 
     int n = 4000000; 
     long i2 = 1, i1 = 1, Fibo = 0, temp = 1; 
     while(i2 < n) { 
      temp = i1 + i2; 
      i1 = i2; 
      i2 = temp; 
      if(i2 % 2 == 0) 
       Fibo += i2; 
     } 
     System.out.println(Fibo); 
    } 
} 

Answer 1

:하지만, 난 그냥이 최종 세부 사항을 파악하고 일이 내 머리에 가야 계획에 모양을 보여줘 사람이 필요 "논평은 실제로 그것이 그렇게 멀지 않다는 데모를 요청했습니다. 첫째, 직접 번역 :

(define (sum-fibonacci-values) 
    (define n 4000000) 
    (define i2 1) 
    (define i1 1) 
    (define fibo 0) 
    (define temp 1) 
    (let loop() 
    (when (< i2 n) 
     (set! temp (+ i1 i2)) 
     (set! i1 i2) 
     (set! i2 temp) 
     (when (zero? (modulo i2 2)) (set! fibo (+ fibo i2))) 
     (loop))) 
    (write fibo)) 

둘째, 중복 변이를 제거함으로써, "관용"만들고, 대신 새 값을 결합하고, 꼬리 재귀 루프를 사용. 이 코드는 원래와 직접적인 상관 관계가 여전히 참고 :

(define (sum-fibonacci-values) 
    (define n 4000000) 
    (let loop ([i2 1] [i1 1] [fibo 0] [temp 1]) 
    (if (< i2 n) 
     (let* ([temp (+ i1 i2)] 
      [i1 i2] 
      [i2 temp] 
      [fibo (if (zero? (modulo i2 2)) (+ fibo i2) fibo)]) 
     (loop i2 i1 fibo temp)) 
     fibo))) 

마지막으로, 지금은 코드가 명확 것으로, 일부 중복이 있다는 것을 알 수있다. 다음은 정리 된 버전입니다.

(define (sum-fibonacci-values) 
    (define n 4000000) 
    (let loop ([i2 1] [i1 1] [fibo 0]) 
    (if (< i2 n) 
     (let ([i3 (+ i1 i2)]) 
     (loop i3 i2 (if (zero? (modulo i3 2)) (+ fibo i3) fibo))) 
     fibo))) 

Java 코드에서 동일한 정리 작업을 수행 할 수 있습니다. (그러나 그것은 독자에게 운동으로 남았습니다 ...)