하스켈 스테이트 모나드와 바이너리가 모든 것을 출력하지 않는다.

Question

나는 간단한 바이너리 인코딩으로 놀아 왔으며, 대부분 모나드를 추가하기 전까지는 제대로 작동하는 것처럼 보였다. 현재 상태를 사용하여 내가 지금까지 작성한 것에 대한 룩업 테이블을 유지하고 문자열의 이전 인스턴스에 오프셋을 복사하여 복제하지 않고 작성합니다.

나는 체크하고 실행하는 모든 타입을 얻었지만, 체인에서 최종 명령을 쓰는 것만 알았다. 나는 Control.Monad.State.Strict를 사용하는 것으로 바꾸었지만 아무런 차이가 없었으므로 다른 곳에서는 근본적인 오류를 범하고있는 것으로 판단된다. 그러나 나는 어디에서 코드를 기본 기능으로 줄 였는지 모른다. . 또한, 이것을하는 더 관용적 인 방법이 있습니까?

{-# LANGUAGE OverloadedStrings #-} 


import   Control.Applicative 
import qualified Control.Monad.State.Strict as S 
import   Data.Binary.Put 
import qualified Data.ByteString   as BS 
import qualified Data.ByteString.Lazy  as BL 

data SState = SState { 
    wsPosition :: Int 
    -- plus whatever else 
} 

initialState = SState 0 
type StatePut = S.State SState Put 

class StateBinary a where 
    sput :: a -> StatePut 

incPos :: Int -> S.State SState() 
incPos amnt = do 
    (SState p) <- S.get 
    S.put $ SState (p + amnt) 

writeSized :: Int -> (a -> Put) -> a -> StatePut 
writeSized n f x = do 
        incPos n 
        return (f x) 

writeInt32 :: Int -> StatePut 
writeInt32 = writeSized 32 putWord32be . fromIntegral 

writeBS :: BS.ByteString -> StatePut 
writeBS b = writeSized (BS.length b) putByteString b 

data SomeData = SomeData { 
    sdName :: BS.ByteString 
    , sdAge :: Int 
    , sdN :: Int 
} deriving (Show, Eq) 

instance StateBinary SomeData where 
    sput (SomeData nm a n) = do 
      writeBS nm 
      writeInt32 a 
      writeInt32 n 

testData = SomeData "TestName" 30 100 

runSPut :: StateBinary a => a -> BL.ByteString 
runSPut a = runPut $ S.evalState (sput a) initialState 

-- runSPut testData returns "\NUL\NUL\NULd" 

Answer 1

문제는 writeSized이 실제로 바이트 스트림에 쓰지 않는다는 것입니다. return은 Put 계산을 상태 모나드에 랩핑하며 실제로 실행하지는 않습니다. 이 그것을 해결하는 현명한 방법이 될 수 있지만 분명 하나 Put가 (실제로 PutM) 모나드라는 사실을 활용하고 상태 모나드로를 구성하는 모나드 변압기를 사용하는 것입니다 :

{-# LANGUAGE OverloadedStrings #-} 


import   Control.Applicative 
import qualified Control.Monad.State.Strict as S 
import   Data.Binary.Put 
import qualified Data.ByteString   as BS 
import qualified Data.ByteString.Lazy  as BL 

data SState = SState { 
    wsPosition :: Int 
    -- plus whatever else 
} 

initialState = SState 0 
-- S.StateT SState PutM is a composed monad, with a state layer above PutM. 
type StatePut = S.StateT SState PutM() 

class StateBinary a where 
    sput :: a -> StatePut 

incPos :: Int -> StatePut 
incPos amnt = do 
    (SState p) <- S.get 
    S.put $ SState (p + amnt) 

writeSized :: Int -> (a -> Put) -> a -> StatePut 
writeSized n f x = do 
        incPos n 
        -- lift runs a computation in the underlying monad. 
        S.lift (f x) 

writeInt32 :: Int -> StatePut 
writeInt32 = writeSized 32 putWord32be . fromIntegral 

writeBS :: BS.ByteString -> StatePut 
writeBS b = writeSized (BS.length b) putByteString b 

data SomeData = SomeData { 
    sdName :: BS.ByteString 
    , sdAge :: Int 
    , sdN :: Int 
} deriving (Show, Eq) 

instance StateBinary SomeData where 
    sput (SomeData nm a n) = do 
      writeBS nm 
      writeInt32 a 
      writeInt32 n 

testData = SomeData "TestName" 30 100 

runSPut :: StateBinary a => a -> BL.ByteString 
runSPut a = runPut $ S.evalStateT (sput a) initialState 

-- *Main> runSPut testData 
-- "TestName\NUL\NUL\NUL\RS\NUL\NUL\NULd" 

Answer 2

당신이 할 수있는 bytestring Builder (편집 : 이제 대신 bytestring에서 binary에서 하나를 사용하여) : 사용

{-# LANGUAGE OverloadedStrings #-} 

import   Data.Monoid 
import qualified Data.Binary    as B 
import qualified Data.Binary.Builder  as BU 
import qualified Data.ByteString   as BS 
import qualified Data.ByteString.Lazy  as BL 

data SomeData = SomeData { 
    sdName :: BS.ByteString 
    , sdAge :: Int 
    , sdN :: Int 
} deriving (Show, Eq) 

testData :: SomeData 
testData = SomeData "TestName" 30 100 

renderData :: SomeData -> BU.Builder 
renderData (SomeData n a i) = mconcat $ 
    BU.fromByteString n : map (BU.fromLazyByteString . B.encode) [a,i] 

test :: BL.ByteString 
test = BU.toLazyByteString . renderData $ testData 

을 아이디어는 도입 (BU.fromX) 및 추가 작업이 O (1), 당신은 단지에 지불하도록되어 있다는 것입니다으로 다시 변환하면 끝납니다..