델파이에서 월 이름을 숫자로 변환 하시겠습니까?

Question

달 이름을 숫자 1-12로 변환하는 내장 델파이 (XE2)/Windows 메소드가 있습니까? (TFormatSettings.)LongMonthNames[] 자신을 통해 반복하는 대신?

Answer 1

IndexStr에서 StrUtils까지 사용할 수 있습니다. 문자열이없는 경우 -1을 반환합니다.

Caption := IntToStr(
    IndexStr(FormatSettings.LongMonthNames[7], FormatSettings.LongMonthNames) + 1); 

편집 :

Function GetMonthNumber(Const Month:String):Integer; overload; 
begin 
    Result := IndexText(Month,FormatSettings.LongMonthNames)+1 
end; 

Answer 2

내가 방법을 찾을 수없는하지만 난 하나를 쓰기 :
당신이 같이 IndexText을 사용할 수 있습니다 주조 및 사례 감도 문제를 방지하려면. ;-)

function GetMonthNumberofName(AMonth: String): Integer; 
var 
    intLoop: Integer; 
begin 
    Result:= -1; 
    if (not AMonth.IsEmpty) then 
    begin 
    for intLoop := Low(System.SysUtils.FormatSettings.LongMonthNames) to High(System.SysUtils.FormatSettings.LongMonthNames) do 
    begin 
     //if System.SysUtils.FormatSettings.LongMonthNames[intLoop]=AMonth then --> see comment about Case insensitive 
     if SameText(System.SysUtils.FormatSettings.LongMonthNames[intLoop], AMonth) then 
     begin 
     Result:= Intloop; 
     Exit 
     end; 
    end; 
    end; 
end; 

좋아요, 다른 FormatSettings에 대해이 기능을 변경했습니다.

function GetMonthNumberofName(AMonth: String): Integer; overload; 
function GetMonthNumberofName(AMonth: String; AFormatSettings: TFormatSettings): Integer; overload; 

function GetMonthNumberofName(AMonth: String): Integer; 
begin 
    Result:= GetMonthNumberofName(AMonth, System.SysUtils.FormatSettings); 
end; 

function GetMonthNumberofName(AMonth: String; AFormatSettings: TFormatSettings): Integer; 
var 
    intLoop: Integer; 
begin 
    Result:= -1; 
    if (not AMonth.IsEmpty) then 
    begin 
    for intLoop := Low(AFormatSettings.LongMonthNames) to High(AFormatSettings.LongMonthNames) do 
    begin 
     if SameText(AFormatSettings.LongMonthNames[intLoop], AMonth) then 
     begin 
     Result:= Intloop; 
     Exit 
     end; 
    end; 
    end; 
end; 

전화

GetMonthNumberofName('may'); 

또는 FormatSetting

procedure TForm1.Button4Click(Sender: TObject); 
var 
    iMonth: Integer; 
    oSettings:TFormatSettings; 
begin 
    // Ned 
    // oSettings:= TFormatSettings.Create(2067); 
    // Fr 
    // oSettings:= TFormatSettings.Create(1036); 
    // Eng 
    oSettings:= TFormatSettings.Create(2057); 
    iMonth:= GetMonthNumberofName(self.Edit1.Text, oSettings); 
    showmessage(IntToStr(iMonth)); 
end;