GTK 버튼의 클릭 된 동작에 사용자 정의 함수를 어떻게 연결합니까?

Question

저는 Elementary OS에서 제공하는 Vala GTK + 3 튜토리얼을 진행 중입니다. 이 코드는 다음과 같음을 알고 있습니다.

var button_hello = new Gtk.Button.with_label ("Click me!"); 
button_hello.clicked.connect (() => { 
    button_hello.label = "Hello World!"; 
    button_hello.set_sensitive (false); 
}); 

클릭하면 버튼의 라벨을 변경하는 데 람다 함수가 사용됩니다. 내가 컴파일 할 때 컴파일

button.clicked.connect(clicked_button(button)); 

하지만 난 발라에서이 오류가 발생합니다 : :이 시도했습니다

void clicked_button(Gtk.Button sender) { 
    sender.label = "Clicked. Yippee!"; 
    sender.set_sensitive(false); 
} 

: 내가 뭘 원하는 대신이 함수를 호출이다

hello-packaging.vala:16.25-16.46: error: invocation of void method not allowed as expression 
    button.clicked.connect(clicked_button(button)); 
          ^^^^^^^^^^^^^^^^^^^^^^ 
Compilation failed: 1 error(s), 0 warning(s) 

저는 Vala와 Linux에 익숙하지 않으므로 친절하게 대해주십시오. 누군가 올바른 방향으로 나를 가리킬 수 있습니까?

Answer 1

함수의 결과가 아닌 함수에 대한 참조를 전달해야합니다. 그래서되어야합니다 : 버튼을 클릭하면

button.clicked.connect (clicked_button);

은 GTK +는 인수로 버튼으로 clicked_button 함수를 호출합니다.

invocation of void method not allowed as expression은 메서드를 호출하는 (호출하는) 오류 메시지가 표시되며 결과가 없습니다 (void). 함수 이름 끝에 괄호 (())를 추가하면 해당 함수가 호출됩니다.

Answer 2

관리가 제대로 작동합니다. 다른 사람들이 필요로 할 경우을 대비해 다음 코드가 있습니다.

int main(string[] args) { 
    // Initialise GTK 
    Gtk.init(ref args); 

    // Configure our window 
    var window = new Gtk.Window(); 
    window.set_default_size(350, 70); 
    window.title = "Hello Packaging App"; 
    window.set_position(Gtk.WindowPosition.CENTER); 
    window.set_border_width(12); 
    window.destroy.connect(Gtk.main_quit); 

    // Create our button 
    var button = new Gtk.Button.with_label("Click Me!"); 
    button.clicked.connect(clicked_button); 

    // Add the button to the window 
    window.add(button); 
    window.show_all(); 

    // Start the main application loop 
    Gtk.main(); 
    return 0; 
} 

// Handled the clicking of the button 
void clicked_button(Gtk.Button sender) { 
    sender.label = "Clicked. Yippee!"; 
    sender.set_sensitive(false); 
}