XSLT 2.0을 사용하여 텍스트 파일에서 읽을 때 상위 요소를 추가하는 방법은 무엇입니까?

Question

XSLT 2.0을 사용하여 텍스트 파일을 읽고 XML을 출력해야합니다.

Start:000,A:123,B:234,C:33,End:99,Start:03,A:123d,B:234s,End:992,Start:a00,B:234,C:33,End:99 

그리고 원하는 XML 출력은 같은 것입니다 : 입력 텍스트 파일과 같은 것입니다

<File> 
<Rec> 
    <Start>000</Start> 
    <A>123</A> 
    <B>234</B> 
    <C>33</C> 
    <End>99</End> 
</Rec> 
<Rec> 
    <Start>03</Start> 
    <A>123d</A> 
    <B>234s</B> 
    <End>992</End> 
</Rec> 
<Rec> 
    <Start>a00</Start> 
    <B>234</B> 
    <C>33</C> 
    <End>99</End> 
</Rec> 

내가 어려움 "끝"에서 "시작"의 요소를 그룹화하고 부모를 추가하는이 엘리먼트 "Rec". 어떠한 제안? 고마워요!

Answer 1

찾고 싶은 출력을 만들려면 unparsed-text()과 tokenize()을 사용할 수 있습니다. 텍스트 파일에 둘 이상의 행이있을 경우 xsl:analyze-string을 사용할 수도 있습니다.

예 ...

텍스트 입력 (so.txt)

Start:000,A:123,B:234,C:33,End:99,Start:03,A:123d,B:234s,End:992,Start:a00,B:234,C:33,End:99 

XSLT 2.0

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    xmlns:xs="http://www.w3.org/2001/XMLSchema" exclude-result-prefixes="xs"> 
    <xsl:output indent="yes"/> 
    <xsl:strip-space elements="*"/> 

    <xsl:param name="input-encoding" as="xs:string" select="'iso-8859-1'"/> 
    <xsl:param name="input-uri" as="xs:string" select="'so.txt'"/> 

    <xsl:template match="/"> 
     <xsl:variable name="input" select="unparsed-text($input-uri, $input-encoding)"/> 
     <File> 
      <xsl:analyze-string select="$input" regex="\r\n?|\n"> 
       <xsl:non-matching-substring> 
        <xsl:for-each select="tokenize(.,'Start')[string()]"> 
         <Rec> 
          <xsl:for-each select="tokenize(.,',')[string()]"> 
           <xsl:variable name="vals" select="tokenize(.,':')"/> 
           <xsl:element name="{if (position()=1) then 'Start' else $vals[1]}"> 
            <xsl:value-of select="$vals[2]"/> 
           </xsl:element> 
          </xsl:for-each>        
         </Rec> 
        </xsl:for-each> 
       </xsl:non-matching-substring> 
      </xsl:analyze-string> 
     </File> 
    </xsl:template> 

</xsl:stylesheet> 

XML 출력

<File> 
    <Rec> 
     <Start>000</Start> 
     <A>123</A> 
     <B>234</B> 
     <C>33</C> 
     <End>99</End> 
    </Rec> 
    <Rec> 
     <Start>03</Start> 
     <A>123d</A> 
     <B>234s</B> 
     <End>992</End> 
    </Rec> 
    <Rec> 
     <Start>a00</Start> 
     <B>234</B> 
     <C>33</C> 
     <End>99</End> 
    </Rec> 
</File> 

Answer 2

토큰 화 한 다음 그룹화하면됩니다.

<xsl:variable name="raw" as="element()*"> 
    <xsl:for-each select="tokenize(normalize-space(unparsed-text('input.txt')), ',')"> 
    <xsl:element name="{substring-before(., ':')}"> 
     <xsl:value-of select="substring-after(., ':')"/> 
    </xsl:element> 
    </xsl:for-each> 
</xsl:variable> 
<File> 
    <xsl:for-each-group select="$raw" group-starting-with="Start"> 
    <Rec> 
     <xsl:copy-of select="current-group()"/> 
    </Rec> 
    </xsl:for-each-group> 
</File>