펄 소켓 : 증가 포트 사용

Question

에서 나는 다음과 같은 코드가있는 경우 :

cannot create socket Address already in use 

: 내가 한 화면이를 시작하고 다른 화면에서 다른 하나를 시작하면

use IO::Socket::INET; 
use Sys::Hostname; 
use Socket; 


my($addr)=inet_ntoa((gethostbyname(hostname))[4]); 

my $port_to_use = 7777; 

my $socket = new IO::Socket::INET (
     LocalHost => $addr, 
     LocalPort => $port_to_use, 
     Proto => 'tcp', 
     Listen => 5, 
     Reuse => 1 
    ); 
die "cannot create socket $!\n" unless $socket; 
my $client_socket = $socket->accept(); 

, 오류가 발생합니다

죽어가는 대신 사용할 포트를 찾을 때까지 다른 포트 (1 씩 증가)를 사용하려고합니다.

나는 eval으로 die 라인을 변환 할 수 있지만이

제안을 잡을 수 메신저하려고했다?

Answer 1

실제로 고장이 주어진 포트에 바인딩 할 수 있는지가 사용되는 포트에 기인하기 위해 확인하는 정돈 대안입니다. 또한 검사 할 포트 범위를 제한합니다. 코드 in the other answer을 사용하고 어떤 이유로 시스템에서 응용 프로그램이 포트에 바인딩하지 못하는 경우 무한 루프에 빠지게됩니다. 또한 기타 방식 등

#!/usr/bin/env perl 

use strict; 
use warnings; 

use Carp qw(croak); 
use Errno qw(EADDRINUSE); 
use IO::Socket::INET; 
use Sys::Hostname qw(hostname); 
use Socket; 

# These can come from a config file or command line 
# See also https://en.wikipedia.org/wiki/List_of_TCP_and_UDP_port_numbers#Dynamic.2C_private_or_ephemeral_ports 
# https://unix.stackexchange.com/a/39784/2371 

my @port_range = (0xC000, 0xFFFF); 

my $addr = inet_ntoa((gethostbyname(hostname))[4]); 
my $socket; 

TRY_PORT: 
for my $port ($port_range[0] .. $port_range[1]) { 
    warn "Trying port $port\n"; 

    $socket = IO::Socket::INET->new(
     LocalHost => $addr, 
     LocalPort => $port, 
     Proto => 'tcp', 
     Listen => 7, 
     Reuse => 0, 
    ); 

    if ($socket) { 
     warn "Bound to port $port\n"; 
     last TRY_PORT; 
    } 

    if (EADDRINUSE != $!) { 
     croak "Cannot bind to port '$port': $!"; 
    } 
    warn "Port in use, trying the next one\n"; 
} 

$socket->accept 
    or croak "..."; 
# ... 

Answer 2

사용 루프 :

여기

use IO::Socket::INET; 
use Sys::Hostname; 
use Socket; 

my($addr)=inet_ntoa((gethostbyname(hostname))[4]); 

my $port_to_use = 7776; 
my $fail =1; 
my $socket; 

while ($fail == 1){ 
    $port_to_use++; 
    $fail = 0; 
    warn $port_to_use; 
    $socket = IO::Socket::INET->new (
     LocalHost => $addr, 
     LocalPort => $port_to_use, 
     Proto => 'tcp', 
     Listen => 5, 
     Reuse => 0 
    ) or $fail =1; 
} 
warn $socket->accept();