Access VBA 컴파일 오류 잘못된 ParamArray 사용

Question

컨텍스트 : Microsoft Access에서 동적으로 Application.Run을 사용하여 함수를 호출하고 매개 변수를 전달하려고합니다. 내 코드는 다음과 엑셀 2013에서 작동하지만 Access에서 작동하지 않습니다 2013

코드 :

Public Sub Test() 
    Call MethodDynamically("MethodToBeCalled1", "This", "works") 
    Call MethodDynamically("MethodToBeCalled2", "This", "works", "too") 
    Call MethodDynamically("MethodToBeCalled3", "This", "works", "too", "as well") 
End Sub 

Public Sub MethodDynamically(MethodName As String, ParamArray Params() as Variant) 
    Application.Run MethodName, Params 
End Sub 
Public Sub MethodToBeCalled1(Params As Variant) 
    Debug.Print Params(0) & " " & Params(1) 
End Sub 
Public Sub MethodToBeCalled2(Params As Variant) 
    Debug.Print Params(0) & " " & Params(1) & " " & Params(2) 
End Sub 
Public Sub MethodToBeCalled3(Params As Variant) 
    Debug.Print Params(0) & " " & Params(1) & " " & Params(2) & " " & Params(3) 
End Sub 

반환 출력 :

This works 
This works too 
This works too as well 

오류 : Access에서 그러나의 동일한 코드는 오류 : Compile error: Invalid ParamArray use을 제공합니다.

Access VBA에이 코드를 조정하는 방법이 있습니까?

Answer 1

ParamArray를 다른 함수에 직접 전달할 수 없습니다.

는 다음과 같은 시도 :

Public Sub MethodDynamically(MethodName As String, ParamArray Params() as Variant) 
    Dim MyArray As Variant 
    MyArray = Params 
    Application.Run MethodName, MyArray 
End Sub