배치 프로그램에 사용자 인터페이스 추가

Question

이 코드가 있습니다. 이 코드는 무선 랜을 ON한다

C:\Windows\System32\netsh.exe wlan start hostednetwork 

되고, 다른 코드 : I는 SSID 및 암호와 같은 사용자로부터의 적절한 입력을 찍은하는

는

@ECHO OFF 
    :Values 
    SET strSSID= 
    SET strPWD= 
    ECHO Please enter the ssid: 
    SET /p strSSID=SSID: 
    ECHO. 
    ECHO Please enter the password: 
    SET /p strPWD=Password: 

    IF ".%strSSID%"=="." GOTO :TryAgain 
    IF ".%strPWD%"=="." GOTO :TryAgain 

    CALL :HostedNW "%strSSID%" "%strPWD%" 
    pause 
    GOTO :EOF 
    :HostedNW 
    ECHO 
    C:\Windows\System32\netsh.exe wlan set hostednetwor mode=allow ssid="%~1" key="%~2" keyUsage=persistent 
    SET strSSID= 
    SET strPWD= 
    GOTO :EOF 
    :TryAgain 
    CLS 
    ECHO. 
    ECHO One or more inputs weren't correct. 
    ECHO Please try again. 
    ECHO. 
    GOTO :Values 

, 이제 둘째로 코드를 가지고

C:\Windows\System32\netsh.exe wlan stop hostednetwork 

이 코드는 WiFi를 끕니다. 이제 모든 코드를 하나의 코드 형식으로 만들고 적절한 사용자 인터페이스를 표시하려고합니다. 첫 번째 클릭 버튼은 "WiFi 구성"을 표시합니다 두 번째 클릭 버튼은 "켜기"로 표시됩니다 세 번째 클릭 버튼은 "켜기 끄기 " 네 번째로 클릭 할 수있는 버튼은 사용자 인터페이스를 종료합니다.

이며 각각의 버튼은 위에서 언급 한 것과 동일한 방식으로 해당 코드를 실행합니다. 가능한 경우이 파일의 사용자 인터페이스를 개선하는 방법을 제안하십시오. 이 문제를 도와주세요. . .

Answer 1

바라건대 이것은 당신이 찾고있는 라인을 따라 뭔가가 있기를 바랍니다.

@echo off 

:mainmenu 
cls 
echo ********************* 
echo *  WiFi Menu  * 
echo ********************* 
echo * 1. Configure WiFi * 
echo * 2. Enable WiFi * 
echo * 3. Disable WiFi * 
echo * 4. Quit   * 
echo ********************* 
choice /C:1234 >nul 

if %errorlevel% equ 1 goto config 
if %errorlevel% equ 2 goto enable 
if %errorlevel% equ 3 goto disable 
if %errorlevel% equ 4 goto quit 

:quit 
exit /b 

:config 
set "strSSID=" 
set "strPWD=" 

:: Enter the SSID and password 
set /p "strSSID=Please enter the SSID: " 
set /p "strpwd=Please enter the password: " 

:: Ensure that the user input is not empty 
if "%strSSID%"=="" goto tryagain 
if "%strPWD%"=="" goto tryagain 

:: Affiliate the SSID with the password 
netsh wlan set hostednetwork mode=allow ssid="%strSSID%" key="%strPWD%" keyUsage=persistent 
echo Wifi configured 
pause 
goto mainmenu 

:: Inform the user that required information was not supplied 
:tryagain 
cls 
echo. 
echo Please input both an SSID and password. 
echo. 
goto config 

:: Activate the WiFi 
:enable 
netsh wlan start hostednetwork 
echo WiFi enabled 
pause 
goto mainmenu 

:: Disable the WiFi 
:disable 
netsh wlan stop hostednetwork 
echo WiFi disabled 
pause 
goto mainmenu