AWK의 피벗 테이블

Question

배열에서 열 인덱스로 요소를 변환하고 각 열 인덱스에 대해 $ 3 값을 반환해야합니다. gawk 4에 액세스 할 수 없으므로 실제 다차원 배열로 작업 할 수 없습니다.

입력

Name^Code^Count 
Name1^0029^1 
Name1^0038^1 
Name1^0053^1 
Name2^0013^3 
Name2^0018^3 
Name2^0023^5 
Name2^0025^1 
Name2^0029^1 
Name2^0038^1 
Name2^0053^1 
Name3^0018^1 
Name3^0060^1 
Name4^0018^2 
Name4^0025^5 
Name5^0018^2 
Name5^0025^1 
Name5^0060^1 

원하는 출력

Name^0013^0018^0023^0025^0029^0038^0053^0060 
Name1^^^^^1^1^1^ 
Name2^3^3^5^1^1^1^1^ 
Name3^^1^^^^^^1 
Name4^^2^^5^^^^ 
Name5^^^^1^^^^1 

실제 다차원 배열을 사용하지 않고이 작업을 해결하는 방법에 대한 어떤 제안이?

Answer 1

두 개의 "차원"만 있으므로 각 차원에 대해 하나의 배열을 사용하고 계산 된 열 이름을 사용하여 조인 할 수 있습니다. 나는 열이나 행을 정렬하지 않았지만 그 아이디어는 꽤 기초적이다.

#!/usr/bin/awk -f 
# 
BEGIN { FS = "^" } 
(NR == 1) {next} 

{ 
    rows[$1] = 1 
    columns[$2] = 1 
    join_table[$1 "-" $2] = $3 
} 

END { 
    printf "Name" 
    for (col_name in columns) { 
     printf "^%s", col_name 
    } 
    printf "\n" 
    for (row_name in rows) { 
     printf row_name 
     for (col_name in columns) { 
      printf "^%s", join_table[row_name "-" col_name] 
     } 
     printf "\n" 
    } 
} 

Answer 2

다음 솔루션은 정렬을 위해 GNU awk v3.2 기능을 사용합니다. 이것은 다차원 배열을 사용하지 않습니다. 그것은 단지 하나를 시뮬레이트합니다. 이것은 어떤 AWK와 함께 작동하고 당신의 입력 파일에서 발생 순서대로 이름을 유지하면서 수치 계산의 출력을 주문합니다

awk -F"^" ' 
NR>1{ 
    map[$1,$2] = $3 
    name[$1]++ 
    value[$2]++ 
} 
END{ 
    printf "Name" 
    n = asorti(value, v_s) 
    for(i=1; i<=n; i++) { 
     printf "%s%s", FS, v_s[i] 
    } 
    print "" 
    m = asorti(name, n_s) 
    for(i=1; i<=m; i++) { 
     printf "%s", n_s[i] 
     for(j=1; j<=n; j++) { 
      printf "%s%s", FS, map[n_s[i],v_s[j]] 
     } 
     print "" 
    } 
}' file 
Name^0013^0018^0023^0025^0029^0038^0053^0060 
Name1^^^^^1^1^1^ 
Name2^3^3^5^1^1^1^1^ 
Name3^^1^^^^^^1 
Name4^^2^^5^^^^ 
Name5^^2^^1^^^^1 

Answer 3

:

$ cat tst.awk 
BEGIN{FS="^"} 

NR>1 { 
    if (!seenNames[$1]++) { 
     names[++numNames] = $1 
    } 

    if (!seenCodes[$2]++) { 
     # Insertion Sort - start at the end of the existing array and 
     # move everything greater than the current value down one slot 
     # leaving open the slot for the current value to be inserted between 
     # the last value smaller than it and the first value greater than it. 
     for (j=++numCodes;codes[j-1]>$2+0;j--) { 
      codes[j] = codes[j-1] 
     } 
     codes[j] = $2 
    } 

    count[$1,$2] = $3 
} 

END { 
    printf "%s", "Name" 
    for (j=1;j<=numCodes;j++) { 
     printf "%s%s",FS,codes[j] 
    } 
    print "" 

    for (i=1;i<=numNames;i++) { 
     printf "%s", names[i] 
     for (j=1;j<=numCodes;j++) { 
      printf "%s%s",FS,count[names[i],codes[j]] 
     } 
     print "" 
    } 
} 

...

$ awk -f tst.awk file 
Name^0013^0018^0023^0025^0029^0038^0053^0060 
Name1^^^^^1^1^1^ 
Name2^3^3^5^1^1^1^1^ 
Name3^^1^^^^^^1 
Name4^^2^^5^^^^ 
Name5^^2^^1^^^^1