배열을 해시로 변환하여 원하는 열을 추출합니다.

Question

두 개의리스트가 일치하는 배열을 가지고 있는데,이 경우에는 다른 열이있는 행의 목록입니다 (이 경우에는 3 개의 값 "숫자 ") :

나는 시도했다 :

my %row; 
@row{@match_all} = split "\t"; 

및

foreach (@match_all){ 
     my %row; 
     @row{@sample_names} = split "\t"; 
     my @filter= join "\t", @row{@wanted}; 
      push (@wanted_columns, @filter); # 



$VAR1 = { 
'#Genera' => 'namex', 
'sample1' => '0.0024', 
'sample2' => '0.0013', 
'sample3' => '0.0' 
}; 

Answer 1

use strict; 
use warnings qw(all); 
use feature qw(say); 

sub get_row { 
    my ($fh) = @_; 
    my $line = <$fh>; 
    return undef if !defined($line); 

    chomp($line); 
    return [ split(/\t/, $line, -1) ]; 
} 

sub get_row_hr { 
    my ($fh, $headers) = @_; 
    my $line = <$fh>; 
    return undef if !defined($line); 

    chomp($line); 
    my %row; 
    @row{@$headers} = split(/\t/, $line, -1); 
    return \%row; 
} 

{ 
    my @wanted_cols = ('#Genera', 'sample1', 'sample3'); 

    my $fh = \*DATA; 

    my $headers = get_row($fh) 
     or die("Premature EOF\n"); 

    say join "\t", @wanted_cols; 
    while (my $row = get_row_hr($fh, $headers)) { 
     say join "\t", @$row{@wanted_cols}; 
    } 
} 

__DATA__ 
#Genera sample1 sample2 sample3 
Gordonia 0.3 0.1 0.4 
Mycobacterium 0.0032 0.23 0.0 
Ornithinimicrobium 0.06 0.0 0.0 
Pseudomonas 0.3 0.28 0.52 
Halomonas 0.0006 0.1 0.1 
Acinetobacter 0.9 0.02 0.5 
Bacillus 0.4 0.5 0.1 
Klebsiella 0.22 0.4 0.3 
Lactobacillus 0.4 0.0 0.0