vb.net에서 다항식을 그릴 때 Math.NET 라이브러리 사용

Question

VB.Net에서 플롯해야하는 방정식이 있습니다. 이 라이브러리, MATH.Net을 찾았습니다. C#에는 많은 예제가 있습니다.

이 라이브러리를 사용하여 VB.NET에서 다항식 함수를 플로팅 할 수 있습니까?

그렇다면 어떻게됩니까? 인터넷에서 예제를 찾을 수 없었습니다. 그렇지 않다면 아무도 VB.Net의 그래프에 다항식을 그리는 방법에 대한 안내를받을 수 있습니까?

저는 Visual Studio 2010을 사용하고 있으며 Visual Basic (계산기 같은 간단한 응용 프로그램을 만들었습니다)에 대한 경험이 거의 없습니다.

Answer 1

일부 데이터 요소를 생성하여 차트의 시리즈에 추가하십시오. 예를 들어

,

Imports System.Windows.Forms.DataVisualization.Charting 

Public Class Form1 

    Function Polynom(x As Double) As Double 
     Return Math.Pow(x, 3) + Math.Pow(x, 2) + x 
    End Function 

    Function Polynom2(x As Double) As Double 
     Return 3 * Math.Pow(x, 2) + 2 * x + 1 
    End Function 

    Sub CreateChart() 
     Dim xMin = -2.0 
     Dim xMax = 2.0 
     Dim nPoints = 21 
     Dim xInc = (xMax - xMin)/(nPoints - 1) 

     Dim c As New Chart 
     c.Size = New Size(Me.Width * 0.9, Me.Height * 0.9) 
     c.Series.Clear() 

     Dim ca As New ChartArea With {.Name = "ChartArea1"} 
     ca.AxisX.Title = "variable" 
     ca.AxisY.Title = "dependent variable" 
     ca.AxisX.Minimum = xMin 
     ca.AxisX.Maximum = xMax 

     c.ChartAreas.Add(ca) 

     Dim s1 As New Series 
     s1.Name = "Polynomial" 
     s1.MarkerStyle = MarkerStyle.Circle 

     Dim s2 As New Series With { 
      .Name = "Derivative", 
      .MarkerStyle = MarkerStyle.Diamond, 
      .ChartType = SeriesChartType.Line 
      } 

     For i = 0 To nPoints - 1 
      Dim x = xMin + i * xInc 
      s1.Points.AddXY(x, Polynom(x)) 
      s2.Points.AddXY(x, Polynom2(x)) 
     Next 

     c.Series.Add(s1) 
     c.Series.Add(s2) 
     c.Series("Polynomial").ChartType = SeriesChartType.Line 

     Dim lgnd As New Legend With {.Name = "Legend"} 
     c.Legends.Add(lgnd) 
     lgnd.DockedToChartArea = "ChartArea1" 
     lgnd.Docking = Docking.Top Or Docking.Left 
     s1.Legend = "Legend" 
     s2.Legend = "Legend" 

     Me.Controls.Add(c) 

    End Sub 

    Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load 
     Me.Size = New Size(640, 480) 
     Me.Text = "Simple polynomial plot" 
     CreateChart() 

    End Sub 

End Class 

는 그냥 데이터 포인트를 생성에 시리즈에 추가 할 필요가 차트에 다항 함수의 그래프를 플롯