SQL Azure에서 임시 테이블 사용

Question

열 이름이 동적으로 생성되는 피벗 테이블 요소에 쿼리를 쓰고 있습니다.

SET @query = N'SELECT STUDENT_ID, ROLL_NO, TITLE, STUDENT_NAME, EXAM_NAME, '+ 
      @cols + 
      ' INTO ##FINAL 
      FROM 
      (
       SELECT * 
       FROM #AVERAGES 
       UNION 
       SELECT * 
       FROM #MARKS 
       UNION 
       SELECT * 
       FROM #GRACEMARKS 
       UNION 
       SELECT * 
       FROM #TOTAL 
       ) p 
       PIVOT 
       (
       MAX([MARKS]) 
       FOR SUBJECT_ID IN 
       ('+ 
       @cols +') 
      ) AS FINAL 
      ORDER BY STUDENT_ID ASC, DISPLAYORDER ASC, EXAM_NAME ASC;' 

EXECUTE(@query) 

select * from ##FINAL 

이 쿼리는 로컬 데이터베이스에서 제대로 작동하지만 SQL Azure에서는 전역 임시 테이블이 허용되지 않으므로이 쿼리는 작동하지 않습니다.

지금 난 내 로컬 데이터베이스에 #FINAL-##FINA L를 변경하는 경우,하지만

잘못된 개체 이름으로 나에게 오류를 제공 '#FINAL'.

이 문제를 어떻게 해결할 수 있습니까?

Answer 1

좋아, 내가 할 수 있다고 생각하지 않는다고 말한 후에, 나는 길을 가질 수있다. 그래도 추한 데. 바라건대, 당신이 아래의 샘플을 재생할 수 있습니다 귀하의 질의에 적응 (내가 그것을 쓰기를 시도하는 스키마 및 데이터를하지 않고, 너무 까다로운) :

declare @cols varchar(max) 
set @cols = 'object_id,schema_id,parent_object_id' 

--Create a temp table with the known columns 
create table #Boris (
    ID int IDENTITY(1,1) not null 
) 
--Alter the temp table to add the varying columns. Thankfully, they're all ints. 
--for unknown types, varchar(max) may be more appropriate, and will hopefully convert 
declare @tempcols varchar(max) 
set @tempcols = @cols 
while LEN(@tempcols) > 0 
begin 
    declare @col varchar(max) 
    set @col = CASE WHEN CHARINDEX(',',@tempcols) > 0 THEN SUBSTRING(@tempcols,1,CHARINDEX(',',@tempcols)-1) ELSE @tempcols END 
    set @tempcols = CASE WHEN LEN(@col) = LEN(@tempcols) THEN '' ELSE SUBSTRING(@tempcols,LEN(@col)+2,10000000) END 
    declare @sql1 varchar(max) 
    set @sql1 = 'alter table #Boris add [' + @col + '] int null' 
    exec (@sql1) 
end 

declare @sql varchar(max) 
set @sql = 'insert into #Boris (' + @cols + ') select ' + @cols + ' from sys.objects' 
exec (@sql) 

select * from #Boris 

drop table #Boris 

그들은 키는 임시 테이블을 만드는 것입니다 바깥 쪽 범위에서 내부 범위 (EXEC 문 내에서 실행되는 코드)는 동일한 임시 테이블에 액세스 할 수 있습니다. 위의 내용은 SQL Server 2008에서 작동했지만 Azure 인스턴스가 없으므로 테스트하지 않았습니다.

Answer 2

임시 테이블을 만들면 spid에서 실행되는 동적 SQL에서 볼 수 있습니다. 동적 SQL에서 테이블을 만들면 테이블 외부에 표시되지 않습니다.

해결 방법이 있습니다. 스텁 테이블을 만들고 동적 SQL에서 변경할 수 있습니다. 약간의 문자열 조작이 필요하지만이 기술을 사용하여 tsqlunit에 대한 동적 데이터 세트를 생성했습니다.

CREATE TABLE #t1 
(
    DummyCol int 
) 

EXEC(N'ALTER TABLE #t1 ADD foo INT') 

EXEC ('insert into #t1(DummyCol, foo) 
VALUES(1,2)') 

EXEC ('ALTER TABLE #t1 DROP COLUMN DummyCol') 

select *from #t1