특정 드라이브가있는 NSIS SelectFolderDialog

NSIS SelectFolderDialog에서 어떻게하면 HDD가있는 트리 만 표시 할 수 있습니까? 사용자가 HDD에없는 디렉토리를 선택하지 못하게해야합니다.특정 드라이브가있는 NSIS SelectFolderDialog

출처

2016-11-23 Erlas

은 무엇 정확히 HDD에 의해 의미합니까 :

또 다른 방법은 사용자가 당신에게 받아 들일 수없는 무언가를 선택한 후 OK 버튼을 비활성화하는 것입니다? 네트워크가 아닌가? 플로피 및 cdrw를 제외하고 특히 로컬 하드 드라이브? – Anders

Vista에서 네트워크 위치를 가리키는 HDD에 심볼릭 링크를 만들 수 있음을 기억하십시오. – Anders

예, 로컬 하드 드라이브 만, 플로피, cdrw 등 제외. – Erlas

어떤 항목이 존재하는지 완전히 제어하려면 SHBrowseForFolder을 호출하고 IFolderFilterSite의 구현을 제공하는 사용자 지정 NSIS 플러그 인을 작성해야합니다.

!include LogicLib.nsh 

!ifndef DRIVE_FIXED 
!define DRIVE_FIXED 3 
!endif 
; This function decides which items are acceptable 
Function MyFolderValidator ; Input: $1=PIDL, $2=Path Output:$0=0 if invalid 
System::Call 'KERNEL32::GetVolumePathName(tr2, t.r4, i ${NSIS_MAX_STRLEN})i.r5' 
${If} $5 <> 0 
    StrCpy $2 $4 
${ElseIf} $5 == "error" ; GetVolumePathName is Win2000+ 
    StrCpy $2 $2 3 ; GetDriveType only accepts root paths (This will not work for UNC) 
${EndIf} 
System::Call 'KERNEL32::GetDriveType(tr2)i.r3' 
${If} $3 = ${DRIVE_FIXED} 
    StrCpy $0 1 ; Allow this path 
${Else} 
    StrCpy $0 0 ; Don't allow this path 
${EndIf} 
FunctionEnd 

!include WinMessages.nsh 
!define /math BFFM_ENABLEOK ${WM_USER} + 101 
!define BFFM_SELCHANGED 2 
!define BFFM_VALIDATEFAILEDA 3 
!define BFFM_VALIDATEFAILEDW 4 
!if "${NSIS_CHAR_SIZE}" > 1 
!define BFFM_VALIDATEFAILED ${BFFM_VALIDATEFAILEDW} 
!else 
!define BFFM_VALIDATEFAILED ${BFFM_VALIDATEFAILEDA} 
!endif 
!if "${NSIS_PTR_SIZE}" <= 4 
Function BrowseForValidatedFolder ; NSIS 2.51+ 
System::Store S 
Pop $2 ; HeadingText 
Pop $1 ; ValidatorFunc 
System::Get "(p.R1, i.R2, p.R3, p)i R8R8" ; BFFCALLBACK 
Pop $R9 ; The system plug-in callback function 
StrCpy $4 "kR9" ; SHBrowseForFolder callback parameter 
System::Call '*(&t261 "")p.r7' ; pszDisplayName buffer 
System::Call '*(p $hwndparent, p0, pr7, t r2, i 0x51, $4, p0, i)p.r8' ; BROWSEINFO struct 
!if "${NSIS_CHAR_SIZE}" > 1 
System::Call 'SHELL32::SHBrowseForFolderW(pr8)p.r9' 
!else 
System::Call 'SHELL32::SHBrowseForFolderA(pr8)p.r9' 
!endif 
BFFCALLBACK_loop: 
    StrCpy $R8 $R8 8 ; HACKHACK: Working around 2.x bug where the callback IDs are never released 
    StrCmp $R8 "callback" 0 BFFCALLBACK_done 
    ${If} $R2 = ${BFFM_SELCHANGED} 
    ${AndIf} $R3 P<> 0 
     System::Store S 
     StrCpy $0 $1 
     StrCpy $1 $R3 
     System::Call 'SHELL32::SHGetPathFromIDList(p $R3, t.r2)' 
     Call $0 
     SendMessage $R1 ${BFFM_ENABLEOK} 0 $0 
     System::Store L 
    ${EndIf} 
    StrCpy $R8 0 ; Yep, the return value is in the same place as the callback id 
    ${IfThen} $R2 = ${BFFM_VALIDATEFAILED} ${|} StrCpy $R8 1 ${|} ; Keep the dialog open 
    System::Call $R9 
    goto BFFCALLBACK_loop 
BFFCALLBACK_done: 
System::Free $R9 ; BFFCALLBACK 
System::Free $7 ; pszDisplayName 
System::Free $8 ; BROWSEINFO 
${If} $9 Z<> 0 
    System::Call 'SHELL32::SHGetPathFromIDList(p r9, t.s)i' 
    System::Call 'OLE32::CoTaskMemFree(p r9)' 
${Else} 
    Push "" ; Error/cancel, return empty string 
${EndIf} 
System::Store L 
FunctionEnd 
!endif 
!macro BrowseForValidatedFolder HeadingText ValidatorFuncName VarResult 
GetFunctionAddress ${VarResult} ${ValidatorFuncName} 
Push ${VarResult} 
Push "${HeadingText}" 
Call BrowseForValidatedFolder 
Pop ${VarResult} 
!macroend 

Section 
!insertmacro BrowseForValidatedFolder "Choose a location for blah blah" MyFolderValidator $0 
${If} $0 != "" 
    MessageBox mb_ok "Result: $0" 
${Else} 
    MessageBox mb_iconstop "User cancelled" 
${EndIf} 
SectionEnd

출처

2016-11-23 18:12:24 Anders

특정 드라이브가있는 NSIS SelectFolderDialog

답변

관련 문제