단어 vba로 단어를 Excel로 복사하여 붙여 넣는 방법

Question

Word 문서가 열릴 때 Excel이 열리지 않고 Word 문서의 seartain BOOkmark에 Excel 파일을 삽입하고 싶습니다.

1. 열린 파일 대화 상자가 맨 아래에있는 팝업 창을 만들려고합니다. 을 (그러나 나는 단어에 그것을 할 수 있도록 만 ??? 내가 코드를 변경하는 방법 단어 VBA 작동하지 않습니다 엑셀 VBA에서 작동)

Sub openfile() 
Dim intChoice As Integer 
Dim strPath As String 
Application.FileDialog(msoFileDialogOpen).AllowMultiSelect = False 
intChoice = Application.FileDialog(msoFileDialogOpen).Show 
If intChoice <> 0 Then 
strPath = Application.FileDialog(_ 
msoFileDialogOpen).SelectedItems(1) 
End If 
End Sub 

다음

나는 코드는 다음과 같다 복사 및 붙여 넣기 아래 제작 : 은 (또한 엑셀에서 L 코드가 어떻게 워드 VBA에만 작업 변경?)

Sub CopyWorksheetsToWord() 
Dim wdApp As Word.Application, wdDoc As Word.Document, ws As Worksheet 
Application.ScreenUpdating = False 
Application.StatusBar = "Creating new document..." 
Set wdApp = New Word.Application 
Set wdDoc = wdApp.Documents.Add 
For Each ws In ActiveWorkbook.Worksheets 

ws.UsedRange.Copy 
wdDoc.Paragraphs(wdDoc.Paragraphs.Count).Range.InsertParagraphAfter 
wdDoc.Paragraphs(wdDoc.Paragraphs.Count).Range.Paste 
Application.CutCopyMode = False 
wdDoc.Paragraphs(wdDoc.Paragraphs.Count).Range.InsertParagraphAfter 
If Not ws.Name = Worksheets(Worksheets.Count).Name Then 
    With wdDoc.Paragraphs(wdDoc.Paragraphs.Count).Range 
     .InsertParagraphBefore 
     .Collapse Direction:=wdCollapseEnd 
     .InsertBreak Type:=wdPageBreak 
    End With 
    End If 
    Next ws 
    Set ws = Nothing 
    Application.StatusBar = "Cleaning up..." 
    With wdApp.ActiveWindow 
    If .View.SplitSpecial = wdPaneNone Then 
    .ActivePane.View.Type = wdNormalView 
    Else 
    .View.Type = wdNormalView 
    End If 
    End With 
    Set wdDoc = Nothing 
    wdApp.Visible = True 
    Set wdApp = Nothing 
    Application.StatusBar = False 
    End Sub 

을

Answer 1

그러면 y ou가 시작되었습니다. 아래 코드를 Word 문서의 'ThisDocument'모듈에 삽입하십시오.

---

은 당신의 말씀을 VBA로 엑셀에 대한 참조를 추가합니다. VBA 편집기에서 도구 및 참조로 이동하십시오. Microsoft Excel 14.0 개체 라이브러리 옆의 확인란을 선택하십시오.

---

Private Sub Document_Open() 
    Dim intChoice As Integer 
    Dim strPath As String 

    Application.FileDialog(msoFileDialogOpen).AllowMultiSelect = False 
    intChoice = Application.FileDialog(msoFileDialogOpen).Show 

    If intChoice <> 0 Then 
     strPath = Application.FileDialog(msoFileDialogOpen).SelectedItems(1) 
    End If 

    CopyWorksheetsToWord (strPath) 
End Sub 


Function CopyWorksheetsToWord(filePath As String) 
    Dim exApp As Excel.Application 
    Dim exWbk As Excel.Workbook 
    Dim exWks As Excel.Worksheet 
    Dim wdDoc As Word.Document 

    Application.ScreenUpdating = False 
    Application.StatusBar = "Creating new document..." 

    Set wdDoc = ActiveDocument 
    Set exApp = New Excel.Application 
    exApp.Visible = False 

    Set exWbk = exApp.Workbooks.Open(filePath) 

    For Each exWks In exWbk.Worksheets 
     exWks.UsedRange.Copy 
     wdDoc.Paragraphs(wdDoc.Paragraphs.Count).Range.InsertParagraphAfter 
     wdDoc.Paragraphs(wdDoc.Paragraphs.Count).Range.Paste 
     exApp.CutCopyMode = False 
     wdDoc.Paragraphs(wdDoc.Paragraphs.Count).Range.InsertParagraphAfter 
     If Not exWks.Name = exWbk.Worksheets(exWbk.Worksheets.Count).Name Then 
      With wdDoc.Paragraphs(wdDoc.Paragraphs.Count).Range 
       .InsertParagraphBefore 
       .Collapse Direction:=wdCollapseEnd 
       .InsertBreak Type:=wdPageBreak 
      End With 
     End If 
    Next exWks 

    Application.StatusBar = "Cleaning up..." 

    Set exWks = Nothing 
    exWbk.Close 
    Set exWbk = Nothing 
    Set exApp = Nothing 

    Application.StatusBar = False 
    Application.ScreenUpdating = True 
End Function 

---

매크로 사용 파일 (.docm)

닫기 워드 파일

열기 워드 파일을 실행합니다 코드와

1. 저장 파일

   

   . 먼저 Excel 파일을 선택하는 파일 열기 상자가 나타납니다.

테스트 코드이지만 오류 검사는 없습니다. 코멘트 당이

---

업데이트

즐겨 찾기는 다음과 같은 구문을 사용하여 이름을 찾을 수 있습니다 :이 경우 내가 책갈피를 삽입하고 라벨에 wdDoc.Bookmarks("Bookmark2").Range

을 Bookmark2

업데이트 된 기능 코드 :

Function CopyWorksheetsToWord(filePath As String) 
    Dim exApp As Excel.Application 
    Dim exWbk As Excel.Workbook 
    Dim exWks As Excel.Worksheet 
    Dim wdDoc As Word.Document 
    Dim bmRange As Range 

    Application.ScreenUpdating = False 
    Application.StatusBar = "Creating new document..." 

    Set wdDoc = ActiveDocument 
    Set exApp = New Excel.Application 
    exApp.Visible = False 

    Set exWbk = exApp.Workbooks.Open(filePath) 

    For Each exWks In exWbk.Worksheets 
     exWks.UsedRange.Copy 

     Set bmRange = wdDoc.Bookmarks("Bookmark2").Range 
     bmRange.Paste 

     exApp.CutCopyMode = False 
     wdDoc.Paragraphs(wdDoc.Paragraphs.Count).Range.InsertParagraphAfter 
     If Not exWks.Name = exWbk.Worksheets(exWbk.Worksheets.Count).Name Then 
      With wdDoc.Paragraphs(wdDoc.Paragraphs.Count).Range 
       .InsertParagraphBefore 
       .Collapse Direction:=wdCollapseEnd 
       .InsertBreak Type:=wdPageBreak 
      End With 
     End If 
    Next exWks 

    Application.StatusBar = "Cleaning up..." 

    Set exWks = Nothing 
    exWbk.Close 
    Set exWbk = Nothing 
    Set exApp = Nothing 

    Application.StatusBar = False 
    Application.ScreenUpdating = True 
End Function 

시트를 반복 할 때마다 서식을 지정하고 문서의 각 섹션을 어떻게 쌓아야하는지 알 수 있지만이 방법을 사용하면 도움이됩니다.