액션 스크립트 3 내가 (그것의 내부 일부와) 간단한와 flex3 프로젝트와 MXML 파일이 디자인 질문

Question

코드와 FMSConnection.as

내가 가진이

public class FMSConnection extends NetConnection 
{ 
    //this methods is called from the media server 
    public function Message(message:String):void 
    { 
     //how to display (add it to a textarea) this message, when this method is invoked ?  
    } 
} 

Answer 1

//in the mxml, after FMSConnection is created: 
fmsConn.addEventListener(FMSConnection.MESSAGE_RECEIVED, onMessage); 

private function onMessage(e:Event):void 
{ 
    fmsConn = FMSConnection(e.target); 
    textArea.text += fmsConn.lastMessage; 
} 

//FMSConnection 
public class FMSConnection extends NetConnection 
{ 
    public static const MESSAGE_RECEIVED:String = "messageReceived"; 

    public var lastMessage:String; 

    public function Message(message:String):void 
    { 
     lastMessage = message; 
     dispatchEvent(new Event(MESSAGE_RECEIVED)); 
    } 
} 

같은 lastMessage 변수를 선언하는 대신 원하는 경우 맞춤 이벤트를 전달하고 메시지를 저장할 수 있습니다. clone 방법을 재정의

//MsgEvent.as 
public class MsgEvent extends Event 
{ 
    public static const MESSAGE_RECEIVED:String = "messageReceived"; 
    public var message:String; 
    public function MsgEvent(message:String, type:String) 
    { 
     super(type); 
     this.message = message; 
    } 
    override public function clone():Event 
    { 
     return new MsgEvent(message, type); 
    } 
} 

//in the mxml, after FMSConnection is created: 
fmsConn.addEventListener(MsgEvent.MESSAGE_RECEIVED, onMessage); 

private function onMessage(e:MsgEvent):void 
{ 
    textArea.text += e.message; 
} 

//FMSConnection 
public class FMSConnection extends NetConnection 
{ 
    public function Message(message:String):void 
    { 
     dispatchEvent(new MsgEvent(message, MsgEvent.MESSAGE_RECEIVED)); 
    } 
} 

이 경우에는 필요하지 않습니다,하지만 사용자 정의 이벤트를 사용하는 동안 수행하는 것이 좋습니다. 복제 메서드를 재정의하지 않으면 이벤트 처리기에서 사용자 지정 이벤트를 재발송하려고 시도하는 동안 런타임 오류가 발생합니다.